如何用数组公式对源数据按指定列重排

weiyingde

1786024734 发表于 2024-8-10 09:17

已更正数据源，但发现单选一个村时，还是没有相应的效果。
见附件

1786024734

1. =INDEX(中考!B:B,MOD(SMALL(IFERROR(FIND(LEFT(中考!$E$2:$E$46,2),$E$1)/1%%+LEFT(RIGHT(中考!$E$2:$E$46,2))/1%+ROW(中考!$E$2:$E$46),10^7-1),ROW(A1)),100))&""

复制代码

weiyingde

1786024734 发表于 2024-8-10 10:57

正在测试，发现一个奇怪的问题，正在查原因，没有解决再问你。

weiyingde

1786024734 发表于 2024-8-10 10:57

发现第99行若有数据，其他空余区域将重复第99行数据。
我知道这是由于最后一个参数：100的原因，反复修改，不达目的，不知为何。
请大侠再看看

1786024734

1. =INDEX(中考!B:B,MOD(SMALL(IFERROR(FIND(LEFT(中考!$E$2:$E$46,2),$E$1)/1%%%+LEFT(RIGHT(中考!$E$2:$E$46,2))/1%%+ROW(中考!$E$2:$E$46),10^8-1),ROW(A1)),1000))&""

复制代码

weiyingde

1786024734 发表于 2024-8-10 12:51

彻底解决问题。
厉害，数组公式使用杠杠的！！！
请结合本例，解析一下公式的含义，并请讲解使用的规则。

谢谢你。

1786024734

weiyingde 发表于 2024-8-10 14:00
彻底解决问题。
厉害，数组公式使用杠杠的！！！
请结合本例，解析一下公式的含义，并 ...

先看用“+”号连接的部分：
①FIND(LEFT(中考!$E$2:$E$46,2),$E$1) 返回【中考】中各行【地址】在 E1 要查询的地址中的位次；
②LEFT(RIGHT(中考!$E$2:$E$46,2))  返回【中考】中各行【地址】中的组数字；
③ROW(中考!$E$2:$E$46) 返回【中考】中各行【地址】对应的行号；

因为【SMALL】不支持一次性多重排序，所以要把上述各结果利用 1% 提升数位后相加起来排序，这里 1%… 也可用 10^x 来代替。因为本例中【中考】数据行超过99行，最大行号为 3 位数，要保证与 ② 的组合后完整不受影响，则 ② 的结果提升数位后 0 位至少要 3 位；同理，① 的结果数位提升后，0 位数要保证 ② 提升数位后和相加后的结果与其相加后完整不受影响，据此来确定 % 的个数或 10^x 中 x 的值 。

④【IFERROR】用来屏蔽【中考】中不符合查询条件的行，当【FIND】函数在 E1 中找不到不符合查询条件的数据时，返回 10^8-1，这个数必须满足 2 个条件：⑴大于前述①②③的所有组合数；⑵后 3 位数大于【中考】表中包含数据行的最大行号。

⑤【SMALL】函数排序。

⑥【MOD】函数对排序结果中的行号进行提取，对应前面 ③ ，所以参数是 1000 。如果符合条件，返回实际行号；否则，返回 999 ，确保该行无数据，不然则按前述规则调整相关数据。

⑦【INDEX】依次函数提取符合条件的数据。

weiyingde

1786024734 发表于 2024-8-10 16:16
先看用“+”号连接的部分：
①FIND(LEFT(中考!$E$2:$E$46,2),$E$1) 返回【中考】中各行【地址】在 E1 要 ...

谢谢帮助。

weiyingde

1786024734 发表于 2024-8-10 16:16
先看用“+”号连接的部分：
①FIND(LEFT(中考!$E$2:$E$46,2),$E$1) 返回【中考】中各行【地址】在 E1 要 ...

弱弱问一句，你对数组函数运用如此顺溜，有否适合的资料和适用的专门书籍。
有资料，分享一下；有好的书籍推介一下。
再次谢谢你。

高山磐石

数组公式，不用拉