隔列按条件提取数据去重汇总求和

天涯论剑 · 发表于 2024-8-4 22:23

要求：第一行红色字体才是需要处理的数据，A列只要卷材，然后按B列，C列，L列，最后去重汇总求和M列

ww87725244 · 发表于 2024-8-4 22:56

=LET(x,CHOOSECOLS(VSTACK(A1:M1,FILTER(A1:M20,A1:A20="卷材")),1,2,3,12,13),GROUPBY(TAKE(x,,4),TAKE(x,,-1),SUM,3))

part98 · 发表于 2024-8-4 23:01

=LET(s,UNIQUE(CHOOSECOLS(FILTER(A1:M20,A1:A20="卷材"),1,2,3,12)),HSTACK(s,BYROW(s,LAMBDA(x,SUM(FILTER(M2:M20,A2:A20&B2:B20&C2:C20&L2:L20=CONCAT(x)))))))

天涯论剑 · 发表于 2024-8-5 01:30

ww87725244 发表于 2024-8-4 22:56
=LET(x,CHOOSECOLS(VSTACK(A1:M1,FILTER(A1:M20,A1:A20="卷材")),1,2,3,12,13),GROUPBY(TAKE(x,,4),TAKE(x, ...

低版本的函数能解决吗

天涯论剑 · 发表于 2024-8-5 01:31

低版本的函数能解决吗

沈默00 · 发表于 2024-8-5 07:43

本帖最后由沈默00 于 2024-8-5 07:46 编辑

函数有了，我来一个数据透视表的

沈默00 · 发表于 2024-8-5 07:44

天涯论剑发表于 2024-8-5 01:31
低版本的函数能解决吗

低版本比较麻烦了，，建议你用数据透视或VBA

沈默00 · 发表于 2024-8-5 08:00

沈默00 · 发表于 2024-8-5 08:01

试一下，，结果放在第二个表里

无关岁月 · 发表于 2024-8-5 09:34

表头需要自己做一下

=IFERROR(INDEX($A:$M,SMALL(IF(MATCH($A$2:$A$20&$B$2:$B$20&$C$2:$C$20&$L$2:$L$20,$A$2:$A$20&$B$2:$B$20&$C$2:$C$20&$L$2:$L$20,)=ROW($1:$19),ROW($2:$20)),ROW(A1)),MATCH(O$1,$A$1:$M$1,)),"")

复制代码

=SUMIFS(M:M,A:A,O2,B:B,P2,C:C,Q2,L:L,R2)

复制代码

		自动登录	找回密码
密码			免费注册

[已解决] 隔列按条件提取数据去重汇总求和

评分

评分

评分

评分