index定位多个值，选择最后一个

279517904 · 发表于 2024-8-2 22:13

uneye2 发表于 2024-8-2 20:20
=IFERROR(INDEX(统计!$A:$Z,SMALL(IF((统计!$C$1:$C$5031=A5)*(统计!$D$1:$DA$5031=B5),ROW($1:$5031),4^8) ...

计算结果空白……

279517904 · 发表于 2024-8-2 22:15

laomu2010 发表于 2024-8-2 19:55
=XLOOKUP(A5&B5,统计!$C$5:$C$12&统计!$D$5:$D$12,统计!$H$5:$H$12,,,-1)

如果最后一个为空值，就会返回空值，
可否匹配最后一个不为空的值

laomu2010 · 发表于 2024-8-2 22:31

本帖最后由 laomu2010 于 2024-8-2 22:44 编辑

=INDEX(H:H,MAX(IF(($C$5:$C$12=C18)*($D$5:$D$12=D18)*($H$5:$H$12<>""),ROW($H$5:$H$12),0)))

整行引用=INDEX($C$5:$H$12,MAX(IF(($C$5:$C$12=C18)*($D$5:$D$12=D18)*($H$5:$H$12<>""),ROW($H$5:$H$12),0))-4,)

uneye2 · 发表于 2024-8-3 13:03

279517904 发表于 2024-8-2 22:13
计算结果空白……

示例.rar (10.38 KB, 下载次数: 1)

279517904 · 发表于 2024-8-3 21:28

根据"合同"表中A、B列，定位"统计"表H列中最后的产值数。
如果最后一个产值数为空，匹配最后一个不为空的值。
结果显示在合同"表中G列
G5格中公式为
=IF(A5=0," ",INDEX(统计!$A$1:$Z$5031,MATCH(A5&B5,统计!$C:$C&统计!$D:$D,0),MATCH("本期审定产值",统计!$4:$4,0)))
如何改造一下

示例.zip (10.2 KB, 下载次数: 5)

part98 · 发表于 2024-8-3 21:39

=LOOKUP(1,0/((统计!$C$5:$C$2000=A5)*(统计!$D$5:$D$2000=B5)*(统计!$H$5:$H$2000<>"")),统计!$H$5:$H$2000）
不是问过一样的问题么

edwin11891 · 发表于 2024-8-3 21:47

=TAKE(FILTER(统计!H$5:H$12,((A5&B5)=(统计!C$5:C$12&统计!D$5:D$12))*(统计!H$5:H$12<>"")),-1)

复制代码

leepoison · 发表于 2024-8-3 21:56

这样吗？

laomu2010 · 发表于 2024-8-3 22:26

本帖最后由 laomu2010 于 2024-8-3 22:30 编辑

昨天因为我把结果区域改到统计表里去了=INDEX(统计!$C$5:$H$12,MAX(IF((统计!$C$5:$C$12=合同!A5)*(统计!$D$5:$D$12=合同!B5)*(统计!$H$5:$H$12<>""),ROW(统计!$H$5:$H$12),0))-4,)
今天也发附件再这里了

279517904 · 发表于 2024-8-3 22:29

part98 发表于 2024-8-3 21:39
=LOOKUP(1,0/((统计!$C$5:$C$2000=A5)*(统计!$D$5:$D$2000=B5)*(统计!$H$5:$H$2000"")),统计!$H$5:$H$2000 ...

感谢，我以为公式计算错误呢，实际是我粗心，
谢谢，谢谢

		自动登录	找回密码
密码			免费注册

[已解决] index定位多个值，选择最后一个

index定位多个值，选择最后一个不为空的值