求高手，给讲解一下代码

戎马书生222

代码是论坛里ooluckydog提供的。有高手能给详细讲解一下吗？


If Not d. exists(专业)Then
Set d(专业)= New Collection
d(专业).Add i
Else
d(专业).Addi
End If
Next

这一段是什么意思？
还有下面一段.

Forj-1 To考场标准人数
arr(d(专业)(1),4) =
arr(d(专业)（1）， 3)= 考场号
d(专业).Remove 1
Next


d(专业)(1)是什么意思？
整体代码能改成字典，不用集合吗？

戎马书生222

求高手给讲解一下。

ykcbf1100

New Collection是一个集合，类似于数组。集合就是一个容器，啥都能往里装。

戎马书生222

For i = 2 To UBound(arr)
            专业 = arr(i, 2)
            If Not d.exists(专业) Then
                Set d(专业) = New Collection
                d(专业).Add i
            Else
                d(专业).Add i
            End If
        Next
这个循环是什么意思？记录行号？
后面那个for循环，能否给讲一下思路。

边缘码农

边缘码农

因为存在尾考场人数的限制，语种西的最后一个考场人数超过了45人。

feilanga

1. Option Explicit
   
2. Sub 考场编排()
   
3.     ' 定义常量：考场标准人数和尾考场人数
   
4.     Const 考场标准人数% = 45, 尾考场人数% = 8
   
5.     ' 声明变量：数组arr，最后一行号lastRow，循环变量i和j，字典对象d，专业名称，考场数，考场号
   
6.     Dim arr(), lastRow&, i&, j&, d As Object, 专业, 考场数%, 考场号%
   
7.     ' 创建字典对象
   
8.     Set d = CreateObject("scripting.dictionary")
   
9.     ' 使用Sheet1工作表
   
10.     With Sheet1
    
11.         ' 获取最后一行的行号
    
12.         lastRow = .Cells(Rows.Count, 1).End(xlUp).Row
    
13.         ' 将A1到D列最后一行的数据赋值给数组arr
    
14.         arr = .Range("a1:d" & lastRow).Value
    
15.         ' 遍历数组arr，从第二行开始
    
16.         For i = 2 To UBound(arr)
    
17.             ' 获取当前行的专业名称
    
18.             专业 = arr(i, 2)
    
19.             ' 如果字典中不存在该专业，则添加到字典中，并创建一个集合
    
20.             If Not d.exists(专业) Then
    
21.                 Set d(专业) = New Collection
    
22.                 d(专业).Add i
    
23.             Else
    
24.                 ' 如果字典中已存在该专业，则将当前行号添加到集合中
    
25.                 d(专业).Add i
    
26.             End If
    
27.         Next
    
28.         ' 遍历字典中的每个专业
    
29.         For Each 专业 In d.keys
    
30.             ' 计算该专业的考场数
    
31.             考场数 = IIf((d(专业).Count Mod 考场标准人数) <= 尾考场人数, d(专业).Count \ 考场标准人数, d(专业).Count \ 考场标准人数% + 1)
    
32.             ' 遍历每个考场，除了最后一个考场
    
33.             For i = 1 To 考场数 - 1
    
34.                 ' 增加考场号
    
35.                 考场号 = 考场号 + 1
    
36.                 ' 遍历每个考场的标准人数
    
37.                 For j = 1 To 考场标准人数
    
38.                     ' 更新数组arr中的考场号和座位号
    
39.                     arr(d(专业)(1), 3) = 考场号
    
40.                     arr(d(专业)(1), 4) = j
    
41.                     ' 从集合中移除已处理的行号
    
42.                     d(专业).Remove 1
    
43.                 Next
    
44.             Next
    
45.             ' 处理最后一个考场
    
46.             考场号 = 考场号 + 1
    
47.             ' 遍历最后一个考场中的所有学生
    
48.             For i = 1 To d(专业).Count
    
49.                 ' 更新数组arr中的考场号和座位号
    
50.                 arr(d(专业)(i), 3) = 考场号
    
51.                 arr(d(专业)(i), 4) = i
    
52.             Next
    
53.         Next
    
54.         ' 清除G1单元格开始的区域内容
    
55.         .[G1].Resize(UBound(arr), UBound(arr, 2)).ClearContents
    
56.         ' 将更新后的数组arr内容写入G1单元格开始的区域
    
57.         .[G1].Resize(UBound(arr), UBound(arr, 2)) = arr
    
58.     End With
    
59. End Sub
    

复制代码