求一个两列数据对账的函数

santrain · 发表于 2024-7-29 09:19

本帖最后由 santrain 于 2024-7-29 09:59 编辑

各位大佬，我要将两列数据做一个简易的对账，A和B两列数据中相同的数两两抵消，最终A列得到右侧的数据，顺序可以不限（但如果能保留抵消后剩余数据在A列中的原次序最好），求一个能直接生成的动态函数

灵犀之声 · 发表于 2024-7-29 09:23

可以用查找函数，把查不到的一一列出来就行

hxj119 · 发表于 2024-7-29 09:36

本帖最后由 hxj119 于 2024-7-29 10:34 编辑

=LET(a,UNIQUE(A2:A99),TEXTSPLIT(CONCAT(REPT(a&",",COUNTIF(A2:A99,a)-COUNTIF(B2:B99,a))),,",",1))

leepoison · 发表于 2024-7-29 09:46

=TEXTSPLIT(CONCAT(LET(a,UNIQUE(A2:A1000),REPT(a&"+",MAP(a,LAMBDA(x,COUNTIF(A2:A1000,x)))-MAP(a,LAMBDA(x,COUNTIF(B2:B1000,x)))))),,"+",TRUE)

part98 · 发表于 2024-7-29 09:51

=LET(s,UNIQUE(A2:A11),TEXTSPLIT(CONCAT(REPT(s&",",COUNTIF(A2:A11,s)-COUNTIF(B2:B9,s))),,",",1))

mjm04 · 发表于 2024-7-29 09:55

本帖最后由 mjm04 于 2024-7-29 10:24 编辑

=FILTER(A2:A11,ISNUMBER(MAP(B2:B11,LAMBDA(_a,IF(COUNTIF(A2:A11,_a)=0,_a,"座")))*1))

注意：
1、A列与 B列的区域必须等长，否则FILTER函数报错！
2、这个是基于B列中数据的位置来的，与数值是否相等无关！

inrever · 发表于 2024-7-29 10:35

=TEXTSPLIT(REDUCE(TEXTJOIN(",",,A2:A11),B2:B9,LAMBDA(m,n,SUBSTITUTE(m,n,"",1))),,",",1)

复制代码

santrain · 发表于 2024-7-29 16:30

inrever 发表于 2024-7-29 10:35

这个函数有个问题，当替换的数字是另一列当中一个数字的其中一部分时，会被错误替换，比如，A列中有个数字是323，B列中有个数字是23，那么就会错误替换剩下3，能否完善一下

inrever · 发表于 2024-7-29 17:29

本帖最后由 inrever 于 2024-7-29 18:44 编辑

santrain 发表于 2024-7-29 16:30
这个函数有个问题，当替换的数字是另一列当中一个数字的其中一部分时，会被错误替换，比如，A列中有个数 ...

=TEXTSPLIT(REDUCE(CONCAT(","&A2:A11&","),B2:B9,LAMBDA(m,n,SUBSTITUTE(m,","&n&",","",1))),,",",1)

我的城市你来过 · 发表于 2024-7-29 19:51

=LET(a,UNIQUE(A2:A11),b,UNIQUE(B2:B9),c,HSTACK(b,COUNTIF(B2:B9,b)),REPT(a,COUNTIF(A2:A11,a)-IFNA(MAP(a,LAMBDA(x,VLOOKUP(x,c,2,0))),0)))

		自动登录	找回密码
密码			免费注册

[已解决] 求一个两列数据对账的函数

评分

评分

评分