一个非常奇怪的问题！

cnmlgb9998

shaowu459 发表于 2024-7-27 09:48
@take试试吧，加个@返回单值。常见问题

谢谢老师，我在外面。回去试试

cnmlgb9998

shaowu459 发表于 2024-7-27 09:48
@take试试吧，加个@返回单值。常见问题

非常感谢 超人大神的 及时帮助！ 成功了。



就加一个 @，成功了。

1. =DROP(
   
2.     REDUCE(
   
3.         0,
   
4.         E2:E6,
   
5.         LAMBDA(x, y,
   
6.             VSTACK(
   
7.                 x,
   
8.                 LET(
   
9.                     _a, SUBSTITUTE(y, CHAR(10), ""),
   
10.                     _b, TEXTSPLIT(_a, , ",", TRUE),
    
11.                     _c, DROP(
    
12.                         REDUCE(
    
13.                             0,
    
14.                             _b,
    
15.                             LAMBDA(m, n,
    
16.                                 IF(
    
17.                                     ISNUMBER(FIND("-", n)),
    
18.                                     LET(
    
19.                                         _d, TEXTSPLIT(n, , "-", TRUE),
    
20.                                         _e, TOCOL(REGEXEXTRACT(_d, "\d+"), 3),
    
21.                                         _f, SEQUENCE(@TAKE(_e, -1) - @TAKE(_e, 1) + 1, , @TAKE(_e, 1), 1),
    
22.                                         VSTACK(m, REGEXEXTRACT(TAKE(_d, 1), "[^0-9]+") & _f)
    
23.                                     ),
    
24.                                     VSTACK(m, n)
    
25.                                 )
    
26.                             )
    
27.                         ),
    
28.                         1
    
29.                     ),
    
30.                     IFNA(HSTACK(OFFSET(y, , -3, , 2), _c), OFFSET(y, , -3, , 2))
    
31.                 )
    
32.             )
    
33.         )
    
34.     ),
    
35.     1
    
36. )

复制代码

shaowu459

cnmlgb9998 发表于 2024-7-27 17:43
非常感谢 超人大神的 及时帮助！ 成功了。

take(x,-1)这种，取出来的是数组，单值也是单值数组。放入不支持数组的函数中，返回值会不符合预期。使用@提取第一个值即可。或者sum，concat之类的聚合一下也行。

cnmlgb9998

shaowu459 发表于 2024-7-27 17:55
take(x,-1)这种，取出来的是数组，单值也是单值数组。放入不支持数组的函数中，返回值会不符合预期。使用 ...

学习了。谢谢大神！！！！！！！！

胡汉三回来了

虽然这里take(array,-1)的结果只有一个数字，但这是一个1行1列的数组，除了加@外，可以套用MAX确定结果中的最大值作为行数，只要使用具有确定的唯一性的函数都可以返回正确结果

cnmlgb9998

胡汉三回来了 发表于 2024-7-29 20:37
虽然这里take(array,-1)的结果只有一个数字，但这是一个1行1列的数组，除了加@外，可以套用MAX确定结果中的 ...

学习了，谢谢！