运用函数快速计算运费（同时满足区域与重量两个条件）

janboor

各位大神，因工作需要，需要以各地区的运费标准，输入地区和重量之后，快速计算出具体运费

请各位大师指教，感激不尽

part98

续重和后面的重量什么关系

dambcer

PQ处理一下，填写蓝色表后刷新后面绿色的出结果

janboor

part98 发表于 2024-7-4 17:52
续重和后面的重量什么关系

比如说发福建，总重量50公斤的话，第一个20公斤算35元，20公斤以外的30公斤是每公斤1元，总共就是35+30*1=65的运费，100公斤以上的话就不需要算这个35元的首重费用，直接100*1就行
不知道这样说明白了没有

janboor

dambcer 发表于 2024-7-4 18:26
PQ处理一下，填写蓝色表后刷新后面绿色的出结果

PQ处理一下是什么意思？小白一个，听不懂

part98

1. =IF(K7<=100,INDEX(B:B,MATCH(J7,A:A,))+MAX(0,(K7-20)*INDEX(C:C,MATCH(J7,A:A,))),K7*INDEX(D:H,MATCH(J7,A:A,),MATCH(K7,{1,3,8,20,30}*100)))

复制代码

janboor

part98 发表于 2024-7-5 17:45

感谢大神，这个可用，不过只能用于100公斤以下的，100公斤以上、300公斤以上、800公斤以上应该再加上什么化代码呢？

part98

janboor 发表于 2024-7-6 07:11
感谢大神，这个可用，不过只能用于100公斤以下的，100公斤以上、300公斤以上、800公斤以上应该再加上什么 ...

这个本身就是可以算所有的

janboor

part98 发表于 2024-7-6 09:26
这个本身就是可以算所有的

确实可以，刚刚搞错一个数字了，真的是帮我大忙了，非常非常感谢

ringo2022

=IF(K6<=100,
    XLOOKUP(J6, A:A, B:B) + MAX(0, (K6-20) * XLOOKUP(J6, A:A, C:C)),
    K6 * XLOOKUP(J6, A:A, CHOOSECOLS(D:H, MATCH(K6, {1, 3, 8, 20, 30}*100)))
)

条件：K6 <= 100
条件为真时的值：
XLOOKUP(J6, A:A, B:B)：查找 J6 在 A 列中的位置，并返回 B 列中的对应值。
MAX(0, (K6-20) * XLOOKUP(J6, A:A, C:C))：查找 J6 在 A 列中的位置，并返回 C 列中的对应值，与 (K6-20) 相乘后取最大值（确保不为负）。
条件为假时的值：
K6 * XLOOKUP(J6, A:A, CHOOSECOLS(D:H, MATCH(K6, {1, 3, 8, 20, 30}*100)))：查找 J6 在 A 列中的位置，并根据 K6 的值在 D:H 列中选择对应的列，然后与 K6 相乘。