请帮忙在标黄的两列设计一下公式

wrnmdd

如图所示是我模拟的一张我日常工作中使用的表格
因为原表格数据巨大 此处我就设计截取了一小段
请帮忙在标黄的两列设计一下公式
具体的需求是这样的：
一、当客户不是“路人甲有限公司”和“炮兵乙有限公司”时
B列单据编号就只保留一个 下面空着
例如:单元格B2 因为对应的客户不是“路人甲有限公司”和“炮兵乙有限公司”   XS202406060053有11行，所以在B列就只保留一行XS202406060053 然后B3—B12为空
C列其实就是B列和F列的组合，也是只保留一行 下面空着
例如：单元格C2，就是 B2+空格+F2+，+F3+，+F4...(以此类推省略)...+F12    然后从C3—C12为空

二、当客户是“路人甲有限公司”和“炮兵乙有限公司”时
B列的单据编号就在A列的基础上增加一个“-1.-2.-3.-4......-n”
例如：单元格B13至B23 因为对应的客户是“路人甲有限公司”和“炮兵乙有限公司” 所以B13就在A13的基础上增加一个“-1”变成XS202406060059-1
B14就在A14的基础上增加一个“-2”变成XS202406060059-2 依次类推一直到B23
C列依然是B列和F列的组合，不过要看对应的A列的单据编号有几行，有几行就需要组合几行
例如：XS202406060059 有11行 则从C13开始 按照 B13+空格+F13的组合规则一直到C23 也是11行

各位表格大咖我这个需求可能在你们看来一点都不难，但对于我这样一个小菜鸟来说可真是要命了
原表格数据量巨大 每天瞅的我眼睛都要瞎了，手指点鼠标和按键盘都要断了 累死我了。
请各位帮忙设计一下公式 谢谢拉

附件.zip (9.69 KB, 下载次数: 8)

2024-7-2 21:57 上传

点击文件名下载附件

part98

1. B2=IF((D2="路人甲有限公司")+(D2="炮兵乙有限公司"),A2&"-"&COUNTIF($A$1:A2,A2),IF(COUNTIF($A$1:A2,A2)=1,A2,""))

复制代码

1. C2=IF((D2="路人甲有限公司")+(D2="炮兵乙有限公司"),A2&"-"&COUNTIF($A$1:A2,A2)&" "&F2,IF(COUNTIF($A$1:A2,A2)=1,A2&" "&TEXTJOIN(",",,FILTER($F$2:$F$34,$A$2:$A$34=A2)),""))

复制代码

jerrike

1. =LET(a,COUNTIF(A$2:A2,A2),b,A2&"-"&a,IF(OR(D2={"路人甲有限公司","炮兵乙有限公司"}),HSTACK(b,b&" "&F2),IF(a=1,HSTACK(A2,A2&" "&TEXTJOIN("，",1,FILTER(F:F,A:A=A2))),"")))

复制代码

zjmhsjbsc951138

这个有点复杂，得知道你的批号

wrnmdd

zjmhsjbsc951138 发表于 2024-7-3 08:53
这个有点复杂，得知道你的批号

是的，在此之前我都是手动搞的 太折磨人了

wrnmdd

jerrike 发表于 2024-7-3 08:32

你好 这个公式 我粘贴在B2 或C2 都显示 #NAME?  请问是怎么回事？是我用的方法不对吗？

jerrike

wrnmdd 发表于 2024-7-3 10:40
你好 这个公式 我粘贴在B2 或C2 都显示 #NAME?  请问是怎么回事？是我用的方法不对吗？

WPS / OFFICE 365版本支持

喂你吃粑粑

B2=

1. =IF(AND(D2<>"路人甲有限公司",D2<>"炮兵乙有限公司"),IF(A2<>A1,A2,""),A2&"-"&COUNTIF($A$2:A2,A2))

复制代码

C2=

1. =IF(AND(D2<>"路人甲有限公司",D2<>"炮兵乙有限公司"),IF(A2<>A1,A2&" "&TEXTJOIN(",",1,FILTER($F$2:$F$34,$D$2:$D$34=D2)),""),A2&"-"&COUNTIF($A$2:A2,A2)&" "&F2)

复制代码

wrnmdd

喂你吃粑粑 发表于 2024-7-3 11:38
B2=C2=

FILTER  这个公式我现在用的wps不支持，还有别的办法吗？公司电脑有还原 一重启就复原了 升级wps也没用

wrnmdd

part98 发表于 2024-7-3 00:49

FILTER  这个公式我现在用的wps不支持，还有别的办法吗？公司电脑有还原 一重启就复原了 升级wps也没用 好气啊！！！