提取奇偶数

ww87725244 · 发表于 2024-6-30 21:41

=TEXTJOIN(" ",,REGEXREPLACE(A1,"[13579]",""),REGEXREPLACE(A1,"[02468]",""))

mykitami · 发表于 2024-6-30 21:55

=LET(a,MID(A1,SEQUENCE(LEN(A1)),1),CONCAT(IF(MOD(a,2)=0,a,""))&" "&CONCAT(IF(MOD(a,2)=1,a,"")))

micch · 发表于 2024-6-30 22:20

复制代码

1786024734 · 发表于 2024-6-30 22:35

=CONCAT(IFERROR(IF(MOD(MID(A2,COLUMN(A:K),1),2)={0;1},MID(A2,COLUMN(A:K),1),"")," "))

复制代码

mjm04 · 发表于 2024-6-30 22:49

=LET(_拆分,MID(A1,SEQUENCE(10,,1),SEQUENCE(10,,1)^0),_偶数,TEXTJOIN(,,FILTER(_拆分,ISEVEN(_拆分))),_奇数,TEXTJOIN(,,FILTER(_拆分,ISODD(_拆分))),_偶数&" "&_奇数)

jivy1212 · 发表于 2024-7-1 08:10

=MID(TEXT(MID(NPV(9,1,IF(MOD(MID(A1,COLUMN(A:J),1),2)={0;1},--MID(A1,COLUMN(A:J),1)),1),3,12),"0 000000"),2,11)

复制代码

低版

wshcw · 发表于 2024-7-1 10:22

由于365我没有安装，无法验证楼上有些公式的正确性。

华尔街操盘手 · 发表于 2024-7-1 10:36

b1下拉

=LET(a,MID(A1,SEQUENCE(LEN(A1)),1),CONCAT(FILTER(a,ISEVEN(--a))," ",FILTER(a,ISODD(--a))))

复制代码

天蚕爱学习 · 发表于 2024-7-1 10:37

=LET(a,REGEXP(A1,"."),CONCAT(TOCOL(IF(ISODD(a),0/0,a),2))&" "&CONCAT(TOCOL(IF(ISODD(a),a,0/0),2)))

天蚕爱学习 · 发表于 2024-7-1 10:39

=LET(a,REGEXP(A1,"."),CONCAT(IF(ISODD(a),"",a),2)&" "&CONCAT(IF(ISODD(a),a,""),2))

		自动登录	找回密码
密码			免费注册

[已解决] 提取奇偶数