在指定日期区间内查询判断是否有相近的值

coee · 发表于 2024-6-30 00:24

coee · 发表于 2024-6-30 01:32

抛砖引玉，看看各位大师有没更好的方法：=TEXTJOIN(",",1,IF((H3:H32+6>=A3)*(H3:H32-6<=A3)*(ABS(I3:I32-B3)<100),TEXT(H3:H32,"yyyy/mm/dd"),""))

mykitami · 发表于 2024-6-30 06:50

=TEXTJOIN("，",,TEXT(FILTER($H$3:$H$32,(ABS($H$3:$H$32-A3)<=7)*(ABS($I$3:$I$32-B3)<=100),"无"),"e/m/d"))

quqiyuan · 发表于 2024-6-30 07:06

=CONCAT(TEXT(IF((ABS($H$3:$H$32-A3)<7)*(ABS($I$3:$I$32-B3)<100),$H$3:$H$32,""),"e/m/d,"))

leepoison · 发表于 2024-6-30 07:08

本帖最后由 leepoison 于 2024-6-30 07:11 编辑

coee 发表于 2024-6-30 01:32
抛砖引玉，看看各位大师有没更好的方法：=TEXTJOIN(",",1,IF((H3:H32+6>=A3)*(H3:H32-6

你不是要第三栏后面写个“无”字吗？

=MAP(A3:A5,LAMBDA(x,IFERROR(TEXTJOIN(",",,TEXT(FILTER(H3:H32,(ABS(I3:I32-OFFSET(x,,1))<=100)*(ABS(H3:H32-x)<=7)),"e/m/d")),"无")))

沈默00 · 发表于 2024-6-30 07:12

=IFERROR(TOROW(FILTER($H$3:$H$32,(ABS($H$3:$H$32-$A3)<=7)*(ABS($I$3:$I$32-$B3)<=100))),"")
下拉公式

沈默00 · 发表于 2024-6-30 07:16

上面结果是分多列显示的
改一下，写在一个单元格里
=IFERROR(TEXTJOIN(";",,TEXT(FILTER($H$3:$H$32,(ABS($H$3:$H$32-$A3)<=7)*(ABS($I$3:$I$32-$B3)<=100)),"e-m-d")),"") 下拉公式

coee · 发表于 2024-6-30 08:20

mykitami 发表于 2024-6-30 06:50
=TEXTJOIN("，",,TEXT(FILTER($H$3:$H$32,(ABS($H$3:$H$32-A3)

谢谢，我的2019测试不到

coee · 发表于 2024-6-30 08:21

quqiyuan 发表于 2024-6-30 07:06
=CONCAT(TEXT(IF((ABS($H$3:$H$32-A3)

结果最后边的逗号怎么去除好些？

coee · 发表于 2024-6-30 08:22

leepoison 发表于 2024-6-30 07:08
你不是要第三栏后面写个“无”字吗？

=MAP(A3:A5,LAMBDA(x,IFERROR(TEXTJOIN(",",,TEXT(FILTER(H3:H32 ...

谢谢，我的2019测试不到

		自动登录	找回密码
密码			免费注册

[求助] 在指定日期区间内查询判断是否有相近的值