请教数组公式提取内容！

amansbj

请从A:I区域内提取满足条件的数据：
条件 1.  当I列中单元格显示为 "在职"
条件 2.    "在职" 所在行的D列中单元格显示 "×"
条件 3.    "在职" 所在行的E列中单元格显示 "×"
条件 4.    "在职" 所在行的F列中单元格显示 "×"
条件 5.    "在职" 所在行的G列中单元格显示 "×"
条件 6.    "在职" 所在行的H列中单元格显示 "×"


如上图例子：同时满足以上6个条件后，提取出王莱少和孙炸憨的数据

hxj119

=INDEX($D$3:$I$15,MATCH(L3&M3,$B$3:$B$15&$C$3:$C$15,0),)

E学子

1. =FILTER(A3:I15,BYROW(D3:I15={"×","×","×","×","×","在职"},LAMBDA(a,AND(a))))

复制代码

1. =FILTER(A3:I15,BYROW(D3:I15={"×","×","×","×","×","在职"},AND))

复制代码

1. =FILTER(A3:I15,MMULT(N(D3:I15={"×","×","×","×","×","在职"}),{1;1;1;1;1;1})=6)

复制代码

amansbj

hxj119 发表于 2024-6-28 09:01
=INDEX($D$3:$I$15,MATCH(L3&M3,$B$3:$B$15&$C$3:$C$15,0),)

老师 您的公式有点问题
不过同样感谢老师的指点

amansbj

E学子 发表于 2024-6-28 09:05

感谢老师，您的公式暂时测试没有问题


为以上两位老师分别奉上花花

inrever

1. =FILTER(A:I,(I:I="在职")*(D:D&E:E&F:F&G:G&H:H=REPT("×",5)))

复制代码

part98

1. =FILTER(A3:I15,(MMULT(--(D3:H15="×"),ROW(1:5)^0)=5)*(I3:I15="在职"))

复制代码

amansbj

inrever 发表于 2024-6-28 09:14

感谢老师，您的公式没有问题，可以实现！


您的这种思路我之前也尝试过，只不过最终没有实现！
我是分别将D列=×&E列=×........然后计算结果只计算出来了所有在职人员的数据！

奉上花花

袁勇

k3：

1. =INDEX(A:A,AGGREGATE(15,6,ROW($3:$15)/1%^(MMULT(($D$3:$H$15="×")*1,{1;1;1;1;1})*($I$3:$I$15="在职")<5),ROW(A1)))

复制代码

右拉下拉。

amansbj

袁勇 发表于 2024-6-28 09:27
k3：右拉下拉。

感谢老师

奉上最后的花花