随机生成50-100数字，总和为400

LP.07 · 发表于 2024-6-25 21:18

LP.07 · 发表于 2024-6-25 21:19

请教大神，这个公式怎样写？

quqiyuan · 发表于 2024-6-25 21:26

规划求解可以不？供参考。。。

无关岁月 · 发表于 2024-6-25 21:43

本帖最后由无关岁月于 2024-6-25 22:21 编辑

如果不满足条件，就多按几次F9

=IF(ROW()=7,B$8-SUM(B$1:B1),RANDBETWEEN(50,80))

复制代码

laomu2010 · 发表于 2024-6-25 22:25

开启迭代计算，

B2=IF(SUM($B$2:$B$7)=400,B2,RANDBETWEEN(50,100))

leepoison · 发表于 2024-6-25 23:05

两个递归自定义
=LAMBDA(x,LET(y,RANDARRAY(6,,50,100,1),IF(SUM(y)=x,y,run(x))))
任意格=run(400)

=LAMBDA(x,LET(y,RANDARRAY(x,,1,6,TRUE),z,FREQUENCY(y,SEQUENCE(1,5)),IF(AND(MIN(z)>=50,MAX(z)<=100),z,kan(x))))
任意格=kan(400)

leepoison · 发表于 2024-6-25 23:14

本帖最后由 leepoison 于 2024-6-26 06:44 编辑

假随机
=FREQUENCY(RANDARRAY(100,,1,6,1),SEQUENCE(5))+50

huanghai22 · 发表于 2024-6-26 11:39

表示参与一下

bsgn2017 · 发表于 2024-6-26 17:15

=LET(a,RANDARRAY(5,,50,100),ROUND(a*(400/SUM(a)),))

复制代码

有一定的偏差，如果要最准确的，建议用定义名称

liuliu2024 · 发表于 2024-6-26 17:37

本帖最后由 liuliu2024 于 2024-6-26 17:40 编辑

=LET(f,LAMBDA(f,x,LET(a,RANDARRAY(6,1,50,100,1),IF(SUM(a)=x,a,f(f,x)))),f(f,400))

复制代码

		自动登录	找回密码
密码			免费注册

[求助] 随机生成50-100数字，总和为400

评分

递归公式，要求excel格式是.xlsx

评分