求SQL Server和Access数据库获取受影响行数的代码

F9458808 · 发表于 2024-6-19 08:13

请教各位大侠，用excel vba操作SQL Server和access数据库时，更新或插入数据时能够获取受影响行数的代码，非常感谢！

一招秒杀 · 发表于 2024-6-19 08:32

SQL Server 有个全局变量@@RowCount，其实这么简单的问题，为啥不问下人工智能或者搜索引擎？都2024年了，还不会用人工智能

，

简直就是新时代的文盲啊

F9458808 · 发表于 2024-6-19 10:44

一招秒杀发表于 2024-6-19 08:32
SQL Server 有个全局变量@@RowCount，其实这么简单的问题，为啥不问下人工智能或者搜索引擎？都2024年了， ...

我说的是在EXCEL里面用VBA操做数据库，获取受影响的行数，就是没有找到答案，才求大侠帮忙的。

opiona · 发表于 2024-6-19 14:06

'*****************************************************************************************
'函数名： AddDelMove
'函数功能：执行SQL语句，一般为添加、修改删除语句
'返回值：返回影响的行数：-2是错误提示
'参数1： StrSQL 字符类型 SQL查询语句
'参数2： Str_coon 字符类型链接语句
'Str_coon = "Provider=Microsoft.JET.OLEDB.4.0;Extended Properties='Excel 8.0;HDR=yes';Data Source=" & ThisWorkbook.FullName '//OFFICE2003
'Str_coon = "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties='Excel 12.0;HDR=yes';Data Source =" & ThisWorkbook.FullName '//OFFICE2007
'Str_coon = "HDR=yes';Data Source =" & FileArr(i) '//OFFICE2003，2007 通用
'使用方法： StrSQL = "DELETE FROM 双色球 WHERE 总序号>1440"
' StrSQL="insert into [sheet1$k2:l6] (f1,f2) values (9,'mine')"
' IntX= AddDelMove(StrSQL, Str_coon)
'*****************************************************************************************
Public Function AddDelMove(ByVal StrSQL As String, ByVal Str_coon As String) As Long '//执行SQL语句，一般为添加、修改删除语句
On Error Resume Next ' 改变错误处理的方式。
Dim iRowscount As Long
Dim CN
Rem Str_coon = "HDR=yes';Data Source=" & ThisWorkbook.FullName
If InStr(UCase(Str_coon), "=SQLOLEDB") > 0 Or InStr(UCase(Str_coon), "={MYSQL") > 0 Then
Rem 如果链接的是MSSQL 或者MySQL 则使用原来的链接字符串, 不做任何处理
Rem Str_coon ="Driver={MySql ODBC 5.3 Unicode Driver};Server=myqcloud.com;Port=7139;DB=test;UID=用户名;PWD=密码;OPTION=3;" '//外网MySQL 没有:WWW 192.168.1.05 没有:\\
Rem Str_coon = "Provider=SQLOLEDB;Server=192.168.1.103;Database=XieXin;Uid=sa;Pwd=1005;" '//SQLServer2005局域网，广域网链接 192.168.1.05 没有:\\
Else
Rem 如果链接: ACCESS Exce 或者WPS
If InStr(UCase(Application.Path), "WPS") > 0 Then
Rem 如果是WPS中使用, 必须是4.0版本的
If InStr(UCase(Str_coon), "PROVIDER=") = 0 Then
Rem 如果是简化的链接字符就补全
Str_coon = "Provider=Microsoft.JET.OLEDB.4.0;Extended Properties='Excel 8.0;" & Str_coon
Rem 完整的WPS链接字符
Rem Str_coon = "Provider=Microsoft.JET.OLEDB.4.0;Extended Properties='Excel 8.0;HDR=yes';Data Source=" & ThisWorkbook.FullName
End If
Else
If InStr(UCase(Str_coon), "PROVIDER=") = 0 Then
Rem 如果是简化的链接字符就补全
If Val(Application.Version * 1) < 12 Then
Rem 2003及以下版本的使用4.0版本引擎
Str_coon = "Provider=Microsoft.Jet.OLEDB.4.0;Extended Properties='Excel 8.0;" & Str_coon
Else
Rem 2007及以上版本的使用12.0版本引擎
Str_coon = "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties='Excel 12.0;" & Str_coon
End If
End If
End If
End If
Err.Clear
If StrSQL = "" Then AddDelMove = -2: Exit Function
Set CN = CreateObject("Adodb.Connection") '//新建一个ADO连接
CN.Open Str_coon
CN.Execute StrSQL, iRowscount, adCmdText '//执行SQL语句,返回影响的行数
Rem CN.Execute(StrSQL,iRowscount) iRowscount操作记录数，比如你插入10条数据，10条数据插入成功，那这个x就等于10
If Err.Number <> 0 Then
MsgBox "Error: " & Err.Description
AddDelMove = -2
Else
AddDelMove = iRowscount
End If
CN.Close '//关闭ADO连接
Set CN = Nothing '//释放内存
End Function

复制代码

F9458808 · 发表于 2024-6-19 18:52

opiona 发表于 2024-6-19 14:06

代码优秀，谢谢大侠！

F9458808 · 发表于 2024-6-19 19:21

本帖最后由 F9458808 于 2024-6-19 19:23 编辑

[quote]F9458808 发表于 2024-6-19 18:52
代码优秀，谢谢大侠！[/quo

F9458808 · 发表于 2024-6-19 19:23

opiona 发表于 2024-6-19 14:06

大侠，能不能再请你帮忙写个代码，就是多人操作SQL Server和Access数据库，解决并发问题，加锁的VBA代码，感谢！

opiona · 发表于 2024-6-20 11:12

F9458808 发表于 2024-6-19 19:23
大侠，能不能再请你帮忙写个代码，就是多人操作SQL Server和Access数据库，解决并发问题，加锁的VBA代码 ...

多人操作SQL Server和Access数据库没问题啊
什么情况还需要特意去下锁, 我到目前还没用过
https://club.excelhome.net/thread-1635846-1-1.html

查询就不用说了
修改时下锁是占用时间太长吗?
可以看看我的百万级数据秒级保存
https://club.excelhome.net/thread-1666858-1-1.html

		自动登录	找回密码
密码			免费注册

[求助] 求SQL Server和Access数据库获取受影响行数的代码

评分