word表格的字体和边框如何设置

1478525

word的表格字体在应用了表格样式后不能完全和表格样式里的一样，需要正文样式和表格样式里的字体格式一样，但平常使用的时候，正文样式这个不太方便改动，于是经常需要手动选表格然后改表格字体，如果使用表样式，表里的格式也不完全一样，只能边框和表格分开设置，想要在表格字体不动的情况下单独设置边框，比如三线表这种，但设置表格样式以后还需要设置段落格式，比较麻烦，如果单独设置框线，批量设置的时候，遇到有合并单元格的时候，代码就停止了，怎么样才能修改代码让这个继续运行。或者跳过合并的表格，继续执行代码呢，谢谢各位大佬老师的指教

Sub 【表格】设置三线表()
    '遍历所有表格
    For Each tbl In ActiveDocument.Tables
        '设置表格顶部和底部边框为1磅
        tbl.Borders(wdBorderTop).LineStyle = wdLineStyleSingle
        tbl.Borders(wdBorderTop).LineWidth = wdLineWidth100pt
        tbl.Borders(wdBorderBottom).LineStyle = wdLineStyleSingle
        tbl.Borders(wdBorderBottom).LineWidth = wdLineWidth100pt
        
      
        '遍历表格中除了第一行和最后一行以外的其余行
        For i = 3 To tbl.rows.count - 1
            tbl.rows(i).Borders(wdBorderTop).LineStyle = wdLineStyleNone
            tbl.rows(i).Borders(wdBorderBottom).LineStyle = wdLineStyleNone
        Next i
        
        '设置第一行下的边框为0.75
        tbl.rows(1).Borders(wdBorderBottom).LineStyle = wdLineStyleSingle
        tbl.rows(1).Borders(wdBorderBottom).LineWidth = wdLineWidth075pt
        
        '隐藏表格的列边框
        For j = 1 To tbl.Columns.count
            tbl.Columns(j).Borders(wdBorderLeft).LineStyle = wdLineStyleNone
            tbl.Columns(j).Borders(wdBorderRight).LineStyle = wdLineStyleNone
        Next j
        
    Next tbl
End Sub
'wdLineWidth025pt    0.25 磅
'wdLineWidth050pt    0.50 磅
'wdLineWidth075pt    0.75 磅
'wdLineWidth100pt    1.00 磅【 默认值】
'wdLineWidth150pt    1.50 磅
'wdLineWidth225pt    2.25 磅
'wdLineWidth300pt    3.00 磅
'wdLineWidth450pt    4.50 磅
'wdLineWidth600pt    6.00 磅

batmanbbs

lss001

Sub 表格设置三线表()
    '遍历所有表格
    Dim tbl As Table, rc As Object
    For Each tbl In ActiveDocument.Tables
        With tbl
            '设置表格顶部和底部边框为1磅=8
            .Borders(-1).LineStyle = 1
            .Borders(-1).LineWidth = 8
            .Borders(-3).LineStyle = 1
            .Borders(-3).LineWidth = 8
        End With
        
        For Each rc In tbl.Range.Cells '对象循环
            With rc
                If .RowIndex = 1 Then
                    '设置第一行下的边框为0.75=6
                    .Borders(-3).LineStyle = 1
                    .Borders(-3).LineWidth = 6
                ElseIf .RowIndex > 2 And .RowIndex < tbl.Rows.Count Then
                    '隐藏表格第三至倒数第二行的行边框
                    .Borders(-1).LineStyle = 0
                    .Borders(-3).LineStyle = 0
                End If
                '隐藏表格的列边框
               
                    .Borders(-2).LineStyle = 0
                    .Borders(-4).LineStyle = 0
               
            End With
        Next
    Next
End Sub

1478525

谢谢您，这个代码试了可以的，请问设置其他的参数比如0.5磅.1.5磅，是等于多少，谢谢大佬

1478525

lss001 发表于 2024-5-29 23:37
Sub 表格设置三线表()
    '遍历所有表格
    Dim tbl As Table, rc As Object

谢谢，经过我自己试了下，0.25磅是2
1磅是8
0.75磅是6
0.5是4,
1.5磅是12
2.25磅是18
3磅是24
但我不知道具体怎么换算，谢谢大佬

1478525

lss001 发表于 2024-5-29 23:37
Sub 表格设置三线表()
    '遍历所有表格
    Dim tbl As Table, rc As Object

您好，我发现如果表格都有边框，运行后会变这样，如果没有边框，运行后是正常的

zhanglei1371

1478525 发表于 2024-5-30 04:52
您好，我发现如果表格都有边框，运行后会变这样，如果没有边框，运行后是正常的

删了这两句：
'隐藏表格的列边框
                'If .RowIndex = 1 Then
  'End If

lss001

1478525 发表于 2024-5-30 04:35
谢谢您，这个代码试了可以的，请问设置其他的参数比如0.5磅.1.5磅，是等于多少，谢谢大佬

https://learn.microsoft.com/zh-cn/dotnet/api/microsoft.office.interop.word.wdlinewidth?view=word-pia
请参考以上wordvba帮助

lss001

1478525 发表于 2024-5-30 04:52
您好，我发现如果表格都有边框，运行后会变这样，如果没有边框，运行后是正常的

代码重点:合并单元格需要→对象循环
For Each rc In tbl.Range.Cells '对象循环
由于您没提供附件，

您可参考楼上老师讲的删除这两句：
'隐藏表格的列边框
                'If .RowIndex = 1 Then
  'End If
或上传附件并说明问题帮您调整。

1478525

zhanglei1371 发表于 2024-5-30 07:34
删了这两句：
'隐藏表格的列边框
                'If .RowIndex = 1 Then

谢谢，删除了还是不行

1478525

lss001 发表于 2024-5-30 08:25
代码重点:合并单元格需要→对象循环
For Each rc In tbl.Range.Cells '对象循环
由于您没提供附件，
...

感谢，第一次不知道要发附件