如何用函数合并重分的排名在一个单元格

黑星殿下s

想问一下各位老师有没有函数可以把重分的对应的姓名放到一个单元格中，然后下面的单元格留空；我这里有这样一张表，一张是各部门得分作为基础数据，主要是要在第二张分部门排名表中，把前面对应的人的得分变为排名，排名相同的要放在同一单元格中，下面留出重排名的对应的空格。
我用index和rank试了一下都不行，麻烦各位老师指教，下附附件

E学子

365可用

1. =LET(a,SCAN(,个人得分总表!$A$3:$A$24,LAMBDA(x,y,IF(y="",x,y))),b,FILTER(个人得分总表!$C$3:$C$24,a=$A3),c,FILTER(个人得分总表!D$3:D$24,a=$A3),d,MATCH(c,SORT(c,,-1),),TEXTJOIN("、",,FILTER(d&"("&b&")",d=$B3,"")))

复制代码

2021可用

1. =LET(a,LOOKUP(ROW(个人得分总表!$A$3:$A$24),1/(个人得分总表!$A$3:$A$24<>"")*ROW(个人得分总表!$A$3:$A$24),个人得分总表!$A$3:$A$24),b,FILTER(个人得分总表!$C$3:$C$24,a=$A3),c,FILTER(个人得分总表!D$3:D$24,a=$A3),d,MATCH(c,SORT(c,,-1),),TEXTJOIN("、",,FILTER(d&"("&b&")",d=$B3,"")))

复制代码

开火车了~作业怕是不太好抄啊

zpy2

create temp table aa as
select fillna(f01) 部门,f03,f04,f05 from 排名合并到一行;
cli_one_dim~temp.aa~2;
//select * from aaunion;
create temp table bb as
select  rank() over (partition by 部门,属性 order by 数量 desc) 排名2,row_number() over (partition by 部门,属性) 排名,f03 姓名,* from aaunion;
//select * from bb;
create temp table cc as
select 部门,属性, 排名2,group_concat(排名2||'('||姓名||')') 姓名  from bb group by 部门,属性,排名2;
//select * from cc;
cli_no_header;
cli_create_two_dim~cc~属性~姓名;
select * from cc_two_dim;

黑星殿下s

E学子 发表于 2024-5-28 10:58
365可用
2021可用
开火车了~作业怕是不太好抄啊

请问LAMBDA函数是什么作用啊？

博爱风雨同舟

C3=LET(A,IFNA((1/(MATCH(A3&个人得分总表!$C$3:$C$24,LOOKUP(ROW($3:$24),ROW($3:$24)/(个人得分总表!$A$3:$A$24<>""),个人得分总表!$A$3:$A$24)&个人得分总表!$C$3:$C$24,)=ROW($1:$22)))*个人得分总表!$D$3:$D$24,0),B,MATCH(A,SORT(A,,-1),),IFERROR(TEXTJOIN("、",1,FILTER(个人得分总表!$C$3:$C$24,B=B3)),""))

E学子

黑星殿下s 发表于 2024-5-28 11:26
请问LAMBDA函数是什么作用啊？

这玩意用文字描述不了~~前面的SCAN要固定搭配一个lamda来使用。在这组公式里，是把一表的合并单元格拆开填充，给后面的查询提供一个条件。和21版公式里的LOOKUP是一个效果

黑星殿下s

E学子 发表于 2024-5-28 11:53
这玩意用文字描述不了~~前面的SCAN要固定搭配一个lamda来使用。在这组公式里，是把一表的合并单元格拆开 ...

好的，谢谢各位老师解答

boyuanoffice

AB列自动溢出公式:

1. A3=DROP(REDUCE("",SCAN(,个人得分总表!A3:A24,LAMBDA(x,y,IF(y="",x,y))),LAMBDA(x,y,VSTACK(x,HSTACK(y,SUM(N(TAKE(x,,1)=y),1))))),1)

复制代码

CD列下拉公式:

1. C3=LET(dat,SORT(FILTER(个人得分总表!$C$3:D$24,$A$3:$A$24=$A3),COLUMN(B$1),-1),df,TAKE(dat,,-1),k,MATCH(df,df,0),ARRAYTOTEXT(FILTER(k&"("&TAKE(dat,,1)&")",k=$B3,"")))

复制代码