求某个值不同条件下的计数

Marco9270

如图，表1为要计算的数据，现求出现某个值的次数，这个值要出现在表1A列的同时，满足表1中B,C,D某个值为“是”的条件，然后如果加上月份的话计数也要计算一下，如图所示的是我ctrl+f找出来的答案，现求用公式表达一下

theking_wsz

附件..................................................

Marco9270

theking_wsz 发表于 2024-5-13 15:49
附件..................................................

附件我检查了，没有问题啊

mykitami

在同一个单元格中出现两个关键词，这怎么算？
比如：A10中的“polo collar sweater women,womens sweater,track suit women”，有两个sweater，那么sweater这人关键词算几个呢？
你现有的这个公式是只算作1个（=COUNTIF(表1!A:A,"*"&A4&"*")）

另外：sweaters 的前半部分是sweater，用=COUNTIF(表1!A:A,"*"&A4&"*")进行计数时，找关键词sweater时，sweaters也进行计数了。
所以，请具体说明一下这些细节问题

Marco9270

mykitami 发表于 2024-5-13 16:44
在同一个单元格中出现两个关键词，这怎么算？
比如：A10中的“polo collar sweater women,womens sweater, ...

第一个：在同个单元格里的算一个
第二个：算值的时候，包含的也算计数

mykitami

Marco9270 发表于 2024-5-13 17:29
第一个：在同个单元格里的算一个
第二个：算值的时候，包含的也算计数

C4
=SUM(COUNTIF(OFFSET(表1!$A$1,ROW(表1!$A$2:$A$18102)-1,),"*"&A4&"*")*(MMULT(N(表1!$B$2:$D$18102="是"),{1;1;1})>0))
D4
=SUM(COUNTIF(OFFSET(表1!$A$1,ROW(表1!$A$2:$A$18102)-1,),"*"&A4&"*")*(表1!$E$2:$E$18102=MONTH(TODAY())-1&"月"))
E4
=SUM(COUNTIF(OFFSET(表1!A1,ROW(表1!$A$2:$A$18102)-1,),"*"&A4&"*")*(MMULT(N(表1!$B$2:$D$18102="是"),{1;1;1})>0)*(表1!$E$2:$E$18102=MONTH(TODAY())-1&"月"))

mykitami

另发一个公式，上面发公式的有些卡
C4
=SUM(ISNUMBER(FIND(A4,表1!$A$2:$A$18102))*(MMULT(N(表1!$B$2:$D$18102="是"),{1;1;1})>0))
D4
=SUM(ISNUMBER(FIND(A4,表1!$A$2:$A$18102))*(表1!$E$2:$E$18102=MONTH(TODAY())-1&"月"))
E4
=SUM(ISNUMBER(FIND(A4,表1!$A$2:$A$18102))*(MMULT(N(表1!$B$2:$D$18102="是"),{1;1;1})>0)*(表1!$E$2:$E$18102=MONTH(TODAY())-1&"月"))

theking_wsz

Marco9270 发表于 2024-5-13 16:24
附件我检查了，没有问题啊

没看到  里面的公式？

Marco9270

theking_wsz 发表于 2024-5-13 18:48
没看到  里面的公式？

第一个公式是我目前自己写的，应该没错，后面的几个不知道所以来问的

Marco9270

mykitami 发表于 2024-5-13 17:57
另发一个公式，上面发公式的有些卡
C4
=SUM(ISNUMBER(FIND(A4,表1!$A$2:$A$18102))*MMULT(N(表1!$B$2:$D$ ...

你好，按公式计算出来的值跟实际查找出来的结果不一样