相同字母后面的数字求和

jiaaizyj · 发表于 2024-5-13 01:11

相同字母后面的数值求和

相同字母即为同一组，求该组中的数值之和。没带字母的为一组，单独求和。

swl4561255 · 发表于 2024-5-13 07:16

I2数组公式，右拉

=SUM(TEXT(SUBSTITUTE($A2:$H2,MID(I1,3,1),),"0;;0;\0")*(LEFT($A2:$H2,1)=MID(I1,3,1)))

复制代码

L2公式：
=SUM(A2:H2)

hugeinfo · 发表于 2024-5-13 07:22

I2=SUM(--SUBSTITUTE(FILTER($A2:$H2, ISNUMBER(FIND("A",$A2:$H2))),"A",""))
J2~K2将上边的A替换为B,S
L2SUM(IFERROR(--$A2:$H2,0))

祝洪忠- · 发表于 2024-5-13 07:24

=SUM((LEFT($A2:$H2)=MID(I1,3,1))*(0&MID($A2:$H2,2,9)))

沈默00 · 发表于 2024-5-13 07:32

I2=LET(x,MID(I$1,3,1),y,$A2:$H2,SUM(SUBSTITUTE(FILTER(y,ISNUMBER(FIND(x,y))),x,"")*1)) 右拉三格
L2=SUM(A2:H2)

hxj119 · 发表于 2024-5-13 09:22

参考公式：
带字母A: =SUM(IFERROR((LEFT(A2:H2)="A")*SUBSTITUTE(A2:H2,"A",),0))
数字求和： =SUM(A2:H2)

ggw092 · 发表于 2024-5-13 10:15

=LET(A,A2:H2,HSTACK(DROP(REDUCE("",MID(I1:K1,3,1),LAMBDA(X,Y,HSTACK(X,SUM(--RIGHT(FILTER(A,ISNUMBER(FIND(Y,A))),1))))),,1),SUM(A)))

复制代码

wlc5201130 · 发表于 2024-5-13 10:37

=SUM(--IF(IF(ISNUMBER($A2:$H2)," ",LEFT($A2:$H2))=MIDB(I1,5,1),RIGHT($A2:$H2),))

复制代码

数组右拉

boyuanoffice · 发表于 2024-5-13 10:49

本帖最后由 boyuanoffice 于 2024-5-13 11:10 编辑

=SUM(IFERROR(--TEXTAFTER($A$2:$H$2,CONCAT(TEXTSPLIT(I1,TEXTSPLIT(I1,{"A","B","S"})))),0))

复制代码

复制代码

mykitami · 发表于 2024-5-13 11:35

=SUM(IFERROR(--TEXTAFTER($A$2:$G$2,MID(I1,3,1)),0))

		自动登录	找回密码
密码			免费注册

[已解决] 相同字母后面的数字求和