VBA-WEB库应用之文字识别API(百度云OCR、腾讯云OCR)

gnefnuy · 发表于 2024-5-9 14:10

本帖最后由 gnefnuy 于 2024-5-9 17:35 编辑

发现一个封装好的WEB操作库，推荐给大家
VBA-Web | VBA-Web (vba-tools.github.io)

应用平台
OCR文字识别_免费试用_图片转文字-百度AI开放平台 (baidu.com)
通用文字识别_图片文字识别_印刷体文字识别-腾讯云 (tencent.com)
我的技术很菜，不喜欢自己造轮子
百度的调用比较简单，创建了一个BaiduAipOcrSDK类模块，token的保持功能我没有写……
WebHelpers模块中添加修改了部分模块，网上有很多的范例，Base64图片文件、UTF8转ANSI等

<blockquote>'这里只能显示一行，删不掉了

复制代码

调用方式是

Private Sub TestOcr01()
Dim result As New Dictionary
Dim tempPath As String
tempPath = "D:\a.jpg"
Dim bdClient As New BaiduAipOcrSDK
bdClient.Setup "你的百度云SecretId", "你的百度云SecretKey"
Set result = bdClient.VehicleLicenseFile(tempPath)
debug.print WebHelpers.ConvertToJson(result, 4)
End Sub

复制代码

腾讯云的比较复杂，有很多坑，我编写了的签名方法v3的版本，调用方式与上面一致，如果大家感兴趣，我再放到本贴中。

gnefnuy · 发表于 2024-5-9 14:25

本帖最后由 gnefnuy 于 2024-5-9 17:39 编辑

[ 本帖最后由 gnefnuy 于 2024-5-9 17:38 编辑 ]\n\n第一段代码被吞了？放这楼吧，或者版主帮助编辑一下，谢谢

' 实现百度云OCR的支持
' gnefnuy 2024.5.9
Option Explicit
Private Const BASE_URL As String = "https://aip.baidubce.com/rest/2.0"
Private Const OCR_URL As String = BASE_URL & "/ocr/v1/"
Private Const IMAGE_CLASSIFY_URL As String = BASE_URL & "/image-classify/v1/"
Public apiKey As String
Public secretKey As String
Public Sub Setup(apiKey As String, secretKey As String)
Me.apiKey = apiKey
Me.secretKey = secretKey
End Sub
' 使用 AK，SK 生成鉴权签名（Access Token）,有效期30天，需加入避免重复获取
Public Function GetAccessToken() As String
Dim token As String
' TODO:先获取本地数据，是否有Token，如果没有就去平台获取
token = "*****可以用30天************"
GetAccessToken = token: Exit Function
Dim client As New WebClient
Dim request As New WebRequest
Dim response As WebResponse
With request
.Resource = "https://aip.baidubce.com/oauth/2.0/token"
.Method = WebMethod.HttpPost
.AddQuerystringParam "grant_type", "client_credentials"
.AddQuerystringParam "client_id", Me.apiKey
.AddQuerystringParam "client_secret", Me.secretKey
End With
Set response = client.Execute(request)
GetAccessToken = response.data("access_token")
End Function
' 通过本地行驶证图片文件识别
Public Function VehicleLicenseFile(Imgpath As String) As Dictionary
Set VehicleLicenseFile = OCR("vehicle_license", Imgpath)
End Function
' 通过行驶证图片网络地址识别
Public Function VehicleLicenseUrl(ImgUrl As String) As Dictionary
Set VehicleLicenseUrl = OCR("vehicle_license", ImgUrl, 2)
End Function
' 通过本地驾驶证图片文件识别
Public Function DrivingLicenseFile(Imgpath As String) As Dictionary
Set DrivingLicenseFile = OCR("driving_license", Imgpath)
End Function
' 通过本地图片识别车牌
Public Function LicensePlateFile(Imgpath As String) As Dictionary
Set LicensePlateFile = OCR("license_plate", Imgpath)
End Function
' 通过本地图片识别VIN
Public Function VinCodeFile(Imgpath As String) As Dictionary
Set VinCodeFile = OCR("vin_code", Imgpath)
End Function
' 通过本地图片识别机动车销售发票
Public Function VehicleInvoiceFile(Imgpath As String) As Dictionary
Set VehicleInvoiceFile = OCR("vehicle_invoice", Imgpath)
End Function
' 通过本地图片识别身份证
Public Function IdcardFile(Imgpath As String) As Dictionary
Set IdcardFile = OCR("idcard", Imgpath)
End Function
' 识别器
' OcrType: 识别类别，按照供应商提供的数据来
' UriType: 0->本地文件路径（默认），2->网络地址，3->BASE64
' body: 对应的相应参数，默认为空
Private Function OCR(OcrType As String, Uri As String, Optional UriType As Integer = 0, Optional body As Dictionary = Nothing) As Dictionary
Dim client As New WebClient
Dim request As New WebRequest
Dim response As WebResponse
Dim body_ As New Dictionary
Dim result As New Dictionary
Set body_ = body
' 设置请求参数
With request
.Resource = OCR_URL & OcrType & "?access_token=" & GetAccessToken()
.Method = WebMethod.HttpPost
.AddHeader "Content-Type", "application/x-www-form-urlencoded"
.AddHeader "Accept", "application/json"
.RequestFormat = FormUrlEncoded
End With
Select Case UriType
Case 0
body_.Add "image", WebHelpers.Base64EncodeFile(Uri) '这里我自己添加的Base64EncodeFile
Case 1
body_.Add "url", Uri
Case 2
body_.Add "image", Uri
End Select
' 将请求正文添加到请求中
Set request.body = body_
' 发送请求并获取响应
Set response = client.Execute(request)
Dim aStr As String
aStr = DecodeToBytes(response.body) '将返回的UTF8字符转为VB可显示的ANSI字符，我自己加的
'aStr = WebHelpers.StringToAnsiBytes(response.body)'或者试试这个自带的
Set result = WebHelpers.ParseJson(aStr)' 我去掉了非ASCII字符的编码，中文不会输出为\u****类的编码
' 输出响应内容
Set OCR = result
End Function

复制代码

opiona · 发表于 2024-5-10 20:46

这个要赞一下

morpheus126 · 发表于 2024-5-10 21:00

谢谢分享，收藏备用

gaolzhen · 发表于 2024-5-11 09:34

不错，学习了

兰色的回忆 · 发表于 2024-5-11 10:24

挺好的，现在百度云收费贵吗

gnefnuy · 发表于 2024-5-11 11:07

opiona 发表于 2024-5-10 20:46
这个要赞一下

感谢大佬，向您学习收获很多。

gnefnuy · 发表于 2024-5-11 11:09

兰色的回忆发表于 2024-5-11 10:24
挺好的，现在百度云收费贵吗

目前OCR类别的百度云和腾讯云都有1000的额度每月，阿里云100个免费额度，我自己用用够了，大项目估计不需要VBA了

gnefnuy · 发表于 2024-5-11 11:32

占个楼，等会儿直接传文件吧，省了字数超限

		自动登录	找回密码
密码			免费注册

[分享] VBA-WEB库应用之文字识别API(百度云OCR、腾讯云OCR)

评分