求值：符合横列2个要求的值求和

安先生_你好 · 发表于 2024-5-5 09:38

各位大大：

求：当B1=F1:M1,B2=F2:M2两个条件时，B3对应的值。

例如：A00003对应销售和202404是20055。

还希望有空指导一下，这个多重横列匹配求和还不会（不是不太会）。这个其实很多列，简化了，如果有这个能省很大的力气，还请各位教导

无关岁月 · 发表于 2024-5-5 09:44

本帖最后由无关岁月于 2024-5-5 09:51 编辑

=SUMPRODUCT((F$1:M$1=B$1)*(F$2:M$2=B$2)*(E$3:E$12=A3)*F$3:M$12)

复制代码

solextrade · 发表于 2024-5-5 09:48

本帖最后由 solextrade 于 2024-5-5 09:58 编辑

=LOOKUP(1,0/(B$1&B$2=F$1:M$1&F$2:M$2),INDEX(F:M,MATCH(A3,E:E,),))

=VLOOKUP(A3,E:M,RIGHT(B$2,2)+1+(B$1="其它")*4,)

swl4561255 · 发表于 2024-5-5 09:52

=SUMPRODUCT((E$3:E$12=A3)*(F$1:M$1=B$1)*(F$2:M$2=B$2)*F$3:M$12)

复制代码

quqiyuan · 发表于 2024-5-5 10:01

=VLOOKUP(A3,E:M,MATCH($B$1&$B$2,$F$1:$M$1&$F$2:$M$2,)+1,)

复制代码

hxj119 · 发表于 2024-5-5 10:06

=SUM(($B$1=$F$1:$M$1)*($B$2=$F$2:$M$2)*($A3=$E$3:$E$12)*$F$3:$M$12)

安先生_你好 · 发表于 2024-5-5 10:32

solextrade 发表于 2024-5-5 09:48
=LOOKUP(1,0/(B$1&B$2=F$1:M$1&F$2:M$2),INDEX(F:M,MATCH(A3,E:E,),))

=VLOOKUP(A3,E:M,RIGHT(B$2,2)+1+ ...

mama
我看见了小罗，他还回我了

安先生_你好 · 发表于 2024-5-5 10:43

感谢各位的无私帮助，恭祝五一最后一天假期快乐。
如果您已上班了，那我已经上班第四天了，今天加班。或许能给您些安慰。

mykitami · 发表于 2024-5-5 11:02

=OFFSET($E$2,MATCH($A3,$E$3:$E$12,),MATCH(B$1&B$2,$F$1:$M$1&$F$2:$M$2,))

ggw092 · 发表于 2024-5-5 11:13

如果店号顺序不变的话，简单一点

=XLOOKUP(B2,F2:M2,F3:M12)

复制代码

		自动登录	找回密码
密码			免费注册

[求助] 求值：符合横列2个要求的值求和

评分

评分

评分

评分

评分