怎么提取混合文本的多个百分数值

银河战舰007 · 发表于 2024-4-29 00:13

根据A列的数据，提取里面的多个百分数，请问应该怎么做可以快速提取出来

solextrade · 发表于 2024-4-29 09:10

=IFERROR(-LOOKUP(,-RIGHT(LEFT(MID($A2,FIND(";",$A2&";")-5,99),FIND("@",SUBSTITUTE(MID($A2,FIND(";",$A2&";")-5,99),"%","@",COLUMN(A1)))),ROW($1:$9))),"")

hxj119 · 发表于 2024-4-29 09:26

本帖最后由 hxj119 于 2024-4-29 09:38 编辑

=TOROW(TEXTAFTER(TEXTSPLIT(A2,"%"),{"单","货"},,,,a)&"%",3)

hxj119 · 发表于 2024-4-29 09:36

只提取订单百分数：
=IFERROR(TOROW(TEXTAFTER(TEXTSPLIT(A2,"%"),"单",,,,a)&"%",3),"")

leepoison · 发表于 2024-4-29 09:43

个人录入数据的不规范，导致清洗要多好多函数

=LET(x,RIGHT(TEXTSPLIT(SUBSTITUTE(SUBSTITUTE(A2,":",""),";",""),"%",,TRUE),4)&"%",RIGHT(x,LEN(x)*2-LENB(x)))

复制代码

cnmlgb9998 · 发表于 2024-4-29 09:43

=IFERROR(DROP(REDUCE("",TEXTSPLIT(A2,VSTACK(";",":"),,TRUE),LAMBDA(x,y,LET(_a,TEXTSPLIT(y,,TEXTSPLIT(y,,VSTACK(SEQUENCE(10)-1,".","%"),TRUE),TRUE),HSTACK(x,LOOKUP(1,0/_a,_a))))),,1),"")

复制代码

chenxuefu · 发表于 2024-4-29 10:00

=SUBSTITUTE(REGEXP(SUBSTITUTE(A9&";",":",";"),"\d+(\.\d+)?%;"),";","")

无关岁月 · 发表于 2024-4-29 10:28

=IFNA(-LOOKUP(1,-RIGHT(LEFT($A2,FIND("@",SUBSTITUTE($A2&";",";","@",COLUMN(A1)))-1),ROW($1:$9))),"")

复制代码

静漠淡然 · 发表于 2024-4-29 11:08

学习了

boyuanoffice · 发表于 2024-4-29 11:17

=REGEXP(A2,"(?<=订单|现货)\d+[\.\d]*%")

复制代码

		自动登录	找回密码
密码			免费注册

[已解决] 怎么提取混合文本的多个百分数值

评分

评分

评分

评分

评分

评分

评分