338. 计数问题，求一个更优算法解

micch

按位计算写个函数

1. Option Explicit
   
2. Sub TEST()
   
3.     Dim res
   
4.     res = Solver(1714, 190)
   
5.     Debug.Print Join(res)
   
6. End Sub
   
7. Function Solver(a As Long, b As Long)
   
8.     Dim res(9) As String, i As Integer
   
9.     If a > b Then Swap a, b
   
10.     For i = 0 To 9
    
11.         res(i) = CountNum(b, i) - CountNum(a - 1, i)
    
12.     Next
    
13.     Solver = res
    
14. End Function
    
15. Function Swap(a As Long, b As Long)
    
16.     Dim c As Long
    
17.     c = a: a = b: b = c
    
18. End Function
    
19. Function CountNum(n0 As Long, i0 As Integer) As Long
    
20.     Dim L0 As Integer, i As Integer
    
21.     Dim Cnt As Long
    
22.     Dim l As Long, r As Long, p As Long
    
23.     L0 = VBA.Len(n0)
    
24.     For i = 1 - (i0 = 0) To L0 Step 1
    
25.         p = 10 ^ (L0 - i)
    
26.         If i > 1 Then
    
27.             l = VBA.Val(VBA.Left(n0, i - 1))
    
28.             Cnt = Cnt + l * p
    
29.             If i0 = 0 Then Cnt = Cnt - p
    
30.         End If
    
31. 
    
32.         Select Case VBA.CInt(VBA.Val(VBA.Mid(n0, i, 1)))
    
33.         Case Is = i0
    
34.             Cnt = Cnt + 1 + VBA.Val(VBA.Mid(n0, i + 1))
    
35.         Case Is > i0
    
36.             Cnt = Cnt + p
    
37.         End Select
    
38.     Next
    
39.     CountNum = Cnt
    
40. End Function

复制代码

1. Option Explicit
   
2. Sub TEST() '主程序输入 a,b 返回10个元素的数组，分别对应0~9的数量
   
3.     Dim res
   
4.     res = Solver(1714, 190) '两个正整数，大小不一
   
5.     Debug.Print Join(res)
   
6. End Sub
   
7. Function Solver(a As Long, b As Long)
   
8.     Dim res(9) As String, i As Integer, c As Long
   
9.     If a > b Then c = a: a = b: b = c '大小相反的话，交换两个数字
   
10.     For i = 0 To 9 '分别统计0~9每个数字的数量
    
11.         res(i) = CountNum(b, i) - CountNum(a - 1, i)
    
12.     Next
    
13.     Solver = res
    
14. End Function
    
15. '统计从0~n0每一个数字中，i0出现的次数
    
16. Function CountNum(n0 As Long, i0 As Integer) As Long
    
17.     Dim L0 As Integer, i As Integer
    
18.     Dim Cnt As Long, p As Long
    
19.     L0 = VBA.Len(n0)
    
20.     '如果i0是0，从第二位开始，1~9从第一位开始
    
21.     '统计每一位的i0的数量
    
22.     For i = 1 - (i0 = 0) To L0 Step 1
    
23.         p = 10 ^ (L0 - i) '数位右侧组合的总数量
    
24.         If i > 1 Then '从第二位开始，计算左侧和右侧合计的组合有多少数字
    
25.             Cnt = Cnt + VBA.Val(VBA.Left(n0, i - 1)) * p
    
26.             If i0 = 0 Then Cnt = Cnt - p '0不能在首位，删除多加的P
    
27.         End If
    
28.         '单独统计右侧组合的数量
    
29.         Select Case VBA.CInt(VBA.Val(VBA.Mid(n0, i, 1)))
    
30.         Case Is = i0
    
31.             Cnt = Cnt + 1 + VBA.Val(VBA.Mid(n0, i + 1))
    
32.         Case Is > i0
    
33.             Cnt = Cnt + p
    
34.         End Select
    
35.     Next
    
36.     CountNum = Cnt
    
37. End Function
    

复制代码