查询字母数字混合的序列缺失的值

496033221

如题，在A列无规则的序列中（不按顺序排列的）查询缺失的值，在F列显示，请大师指点一下

chxw68

1. Sub test()
   
2.     Dim r%
   
3.     Dim arr, brr
   
4.     Dim d As Object
   
5.     Set d = CreateObject("scripting.dictionary")
   
6.     With Worksheets("sheet1")
   
7.         r = .Cells(.Rows.Count, 1).End(xlUp).Row
   
8.         arr = .Range("a2:a" & r)
   
9.         For i = 1 To UBound(arr)
   
10.             d(arr(i, 1)) = Empty
    
11.         Next
    
12.         s1 = Val(Mid(arr(1, 1), 3))
    
13.         s2 = Val(Mid(arr(UBound(arr), 1), 3))
    
14.         ReDim brr(1 To s2 - s1 + 1, 1 To 1)
    
15.         m = 0
    
16.         For i = s1 To s2
    
17.             xm = "9S" & Format(i, "0000000000000")
    
18.             If Not d.exists(xm) Then
    
19.                 m = m + 1
    
20.                 brr(m, 1) = xm
    
21.             End If
    
22.         Next
    
23.         If m > 0 Then
    
24.             .Range("c2").Resize(m, 1) = brr
    
25.         End If
    
26.     End With
    
27. End Sub
    

复制代码

chxw68

详见附件。

gwjkkkkk

Option Explicit
Sub test1()
    Dim ar, br, i&, j&, n&, r&, strHeader$
   
    ar = Range("A2", Cells(Rows.Count, "A").End(xlUp)).Value
    ReDim Preserve ar(1 To UBound(ar), 1)
    strHeader = Mid(ar(1, 0), 1, Len(ar(1, 0)) - 1)
    ReDim br(1 To 10 ^ 6, 0)
   
    For i = 1 To UBound(ar)
        ar(i, 1) = Val(right(ar(i, 0), 5))
    Next i
    qSort ar, 1, UBound(ar) - 1, 0, 1, 1
   
    For i = 1 To UBound(ar) - 1
        If ar(i + 1, 1) - 1 <> ar(i, 1) Then
            n = ar(i + 1, 1) - ar(i, 1) - 1
            For j = 1 To n
                r = r + 1
                br(r, 0) = strHeader & Format(ar(i, 1) + j, "00000")
            Next j
            
        End If
    Next i

    If r Then [B2].Resize(r) = br
    Beep
End Sub


Function qSort(ByRef ar, ByVal iFirst&, ByVal iLast&, ByVal iLeft&, _
    ByVal iRight, Optional ByVal iKey& = 1, Optional isOrder As Boolean = True)
   
    Dim i&, j&, k&, vTemp1, vTemp2
   
    i = iFirst: j = iLast: vTemp1 = ar((iFirst + iLast) / 2, iKey)
    While i <= j
        If isOrder Then
            While ar(i, iKey) < vTemp1: i = i + 1: Wend
            While vTemp1 < ar(j, iKey): j = j - 1: Wend
        Else
            While ar(i, iKey) > vTemp1: i = i + 1: Wend
            While vTemp1 > ar(j, iKey): j = j - 1: Wend
        End If
        If i <= j Then
             For k = iLeft To iRight
             vTemp2 = ar(i, k): ar(i, k) = ar(j, k): ar(j, k) = vTemp2
            Next
            i = i + 1: j = j - 1
        End If
    Wend
   
    If iFirst < j Then qSort ar, iFirst, j, iLeft, iRight, iKey, isOrder
    If i < iLast Then qSort ar, i, iLast, iLeft, iRight, iKey, isOrder
End Function

gwjkkkkk

请参考附件。。。

quqiyuan

cnmlgb9998

用PQ解决，轻轻松松！！！！！！！！！！！！！！！！！！！！！！！！！

cnmlgb9998

大家给你做出来了。怎么没个音讯？ 花舍不得给就算了，回个话也不行吗？兄弟！

ooluckydog

一招秒杀

SQL  1条语句就够了，你们写的是不是有点多多多？！！！