二维表转一维表之TEXT函数

edwin11891 · 发表于 2024-4-10 21:50

本帖最后由 edwin11891 于 2024-4-10 21:51 编辑

如题，在REDUCE等365循环函数之前，二维表转为一维表，使用TEXT（{1，-1}，。。）是比较常用的方法。

但是，在表中数据为纯字母的情况下，转换结果会出错，如图左，数字、中文字符则正确无误，如图中、右。
本论坛上对TEXT（{1，-1}，。。）方法曾经有此一论，但最终也没有说明其原因，因此有此一问，欲知其然。
其中公式是：
=TEXT({1,-1},TOCOL(A1:C1&";"&IF(A2:C6<>"",A2:C6,1/0),3,1))

无关岁月 · 发表于 2024-4-10 21:56

=TEXT({1,-1},""""&TOCOL(A1:C1&""";"""&IF(A2:C6<>"",A2:C6,1/0),3,1)&"""")

复制代码

edwin11891 · 发表于 2024-4-10 22:02

无关岁月发表于 2024-4-10 21:56

这相当于强制转换，原因呢？

无关岁月 · 发表于 2024-4-10 22:05

edwin11891 发表于 2024-4-10 22:02
这相当于强制转换，原因呢？

只会套路，原因就不太清楚了

boyuanoffice · 发表于 2024-4-10 22:53

本帖最后由 boyuanoffice 于 2024-4-10 22:55 编辑

找到一篇文章, 可以参考一下:
Excel Text函数用法的18个实例，含文本日期、条件范围格式与数组{0,1}/{1,-1}详解
http://www.liangshunet.com/ca/201901/236448754.htm

祝洪忠- · 发表于 2024-4-10 22:56

edwin11891 发表于 2024-4-10 22:02
这相当于强制转换，原因呢？

=TEXT({1,-1},TOCOL(A1:C1&";"&IF(A2:C6<>"","!"&A2:C6,1/0),3,1))

这样试试。

部分字符在自定义格式代码中有特殊含义，比如 D 表示天，H 表示时，S 表示秒，M表示月（分钟）等等。

edwin11891 · 发表于 2024-4-11 08:25

本帖最后由 edwin11891 于 2024-4-11 08:39 编辑

祝洪忠- 发表于 2024-4-10 22:56
=TEXT({1,-1},TOCOL(A1:C1&";"&IF(A2:C6"","!"&A2:C6,1/0),3,1))

这样试试。

经检验，对一半。

1. 确实，对于Y、M、D、H、S、M等有特殊含义的字母，原公式出错，此外，G、H也会出错，祝版的公式正确。
2. 错一半的是，祝版的公式，对于DDD、GG、HH、SS、MM、YY、YYYY、DD等字符，依然出错。
现在原因大概是找到了，可公式要怎么避免呢？二楼的方法均正确，但作为通用公式，似乎不那么理想。

咔咔乱坠 · 发表于 2024-4-11 09:05

本帖最后由咔咔乱坠于 2024-4-11 09:08 编辑

就题，不考虑通项
=TEXT({1,-1},TOCOL(A1:C1&";\"&IF(A2:C6>0,A2:C6,\),3,1))
=REDUCE(E1,A1:C1,LAMBDA(x,y,VSTACK(x,IF({1,0},y,TOCOL(OFFSET(y,1,,9),3)))))

edwin11891 · 发表于 2024-4-11 09:14

咔咔乱坠发表于 2024-4-11 09:05
就题，不考虑通项
=TEXT({1,-1},TOCOL(A1:C1&";\"&IF(A2:C6>0,A2:C6,\),3,1))
=REDUCE(E1,A1:C1,LAMBDA(x ...

经检验，公式2没问题，只是需要套一个 DROP 函数去掉第一行即可。

公式1对于DDD、GG、HH、SS、MM、YY、YYYY、DD等字符还是出错；
此外出现新问题，对于A列的数字10，转换后变为11，祝版的公式同样为11。如图。

咔咔乱坠 · 发表于 2024-4-11 09:15

edwin11891 发表于 2024-4-11 09:14
经检验，公式2没问题，只是需要套一个 DROP 函数去掉第一行即可。

公式1对于DDD、GG、HH、SS、MM、YY ...

{1,-1}%

		自动登录	找回密码
密码			免费注册

[讨论] 二维表转一维表之TEXT函数