今日头条刚看到的一道题，很有意思!(前提，不许用groupBY !)

cnmlgb9998 · 发表于 2024-4-6 19:30

如图所示！！！！！！！

cnmlgb9998 · 发表于 2024-4-6 19:31

强调！不许使用 MS测试中的函数如Ｇｒｏｕｐｂｙ　等！！！！！

cnmlgb9998 · 发表于 2024-4-6 19:32

不用 VBA，不用 PQ！

一杯绿茶来了 · 发表于 2024-4-6 19:43

=TEXTJOIN(",",,IFERROR(SCAN(0,A1:A24,LAMBDA(x,y,IF((y="A")*(OFFSET(y,-1,)<>"A"),ROW(y),""))),""))
=TEXTJOIN(",",,MAP(TEXTSPLIT(CONCAT(IF(A1:A24="A",1,"/")),,"/",1),LAMBDA(x,LEN(x))))

无关岁月 · 发表于 2024-4-6 20:42

=TEXTJOIN(",",,IF((A1:A24<>"A")*(A2:A25="A"),ROW(2:25),""))

复制代码

=LET(_a,FREQUENCY(IF(A1:A24="A",ROW(1:24)),IF(A1:A24<>"A",ROW(1:24))),TEXTJOIN(",",,FILTER(_a,_a)))

复制代码

edwin11891 · 发表于 2024-4-6 20:47

行号：

=LET(s,IF(A1:A24="A",1,0),t,FIND("01",CONCAT(s),SEQUENCE(24))+1,TEXTJOIN(",",1,UNIQUE(IFERROR(t,""))))

复制代码

重复数：

=LET(s,CONCAT(IF(A1:A24="A",1,0)),t,TEXTSPLIT(s,,0),x,IF(LEN(t)=0,"",LEN(t)),TEXTJOIN(",",1,x))

复制代码

cnmlgb9998 · 发表于 2024-4-6 20:48

无关岁月发表于 2024-4-6 20:42

大师，厉害！这个错位用得妙！

mykitami · 发表于 2024-4-6 20:56

=LET(a,IF(A1:A24="A",ROW(A1:A24),""),TEXTJOIN(",",,MAP(DROP(a,-1),DROP(a,1),LAMBDA(x,y,IF(AND(x="",y<>""),y,"")))))
=TEXTJOIN(",",,LEN(TEXTSPLIT(CONCAT(IF(A1:A24="A",1,"|")),,"|",1)))

cnmlgb9998 · 发表于 2024-4-6 21:01

mykitami 发表于 2024-4-6 20:56
=LET(a,IF(A1:A24="A",ROW(A1:A24),""),TEXTJOIN(",",,MAP(DROP(a,-1),DROP(a,1),LAMBDA(x,y,IF(AND(x="",y ...

MAP 后面两个常量数组，都是一个一个取数的吗？

mykitami · 发表于 2024-4-6 21:10

cnmlgb9998 发表于 2024-4-6 21:01
MAP 后面两个常量数组，都是一个一个取数的吗？

是的，一个一个取数，并且是一一对应的

		自动登录	找回密码
密码			免费注册

[求助] 今日头条刚看到的一道题，很有意思!(前提，不许用groupBY !)

评分

评分

评分

评分