请教公式如何获取各个分类中的最大值？

Batcher · 发表于 2024-3-27 16:44

A产品最高返点：92.50%，获取对应的销量23
B产品最高返点：19.10%，获取对应的销量77
B产品最高返点：92.80%，获取对应的销量187
以此类推
请教F2:G4的公式应该怎么写？谢谢！

分类最大值.zip (7.22 KB, 下载次数: 35)

qwer401245 · 发表于 2024-3-27 16:48

本帖最后由 qwer401245 于 2024-3-27 16:51 编辑

=TAKE(SORT(FILTER(B:C,A:A=E2),2),-1)

miaojohn45 · 发表于 2024-3-27 16:49

本帖最后由 miaojohn45 于 2024-3-27 16:52 编辑

=MAXIFS($C$2:$C$10,$A$2:$A$10,E2)

=FILTER($B$2:$B$10,($A$2:$A$10=E2)*($C$2:$C$10=G2))

qydn · 发表于 2024-3-27 16:49

=MAX(IF($A$2:$A$10=E2,$C$2:$C$10))

jivy1212 · 发表于 2024-3-27 16:50

复制代码

右拉下拉

袁勇 · 发表于 2024-3-27 16:53

F2：

=INDEX(B:B,MOD(AGGREGATE(14,6,(ROUND($C$2:$C10,2)*10^6+ROW($2:10))/($A$2:$A10=$E2),1),10^2))

复制代码

右拉下拉。或者基本操作，数据透视表，取返点最大值。

quqiyuan · 发表于 2024-3-27 16:54

=INDEX(B:B,RIGHT(MAX(IF($A$2:$A$10=$E2,$C$2:$C$10/1%%%+ROW($2:$10))),2))

浮生若梦~~~ · 发表于 2024-3-27 16:56

=LOOKUP(,0/($A:$A=$E2)/($C:$C=MAXIFS($C:$C,$A:$A,$E2)),B:B)

leepoison · 发表于 2024-3-27 17:00

本帖最后由 leepoison 于 2024-3-27 17:14 编辑

=FILTER($B$2:$C$10,($A$2:$A$10=E2)*($C$2:$C$10=MAX(INDEX(FILTER($B$2:$C$10,$A$2:$A$10=E2),,2))))

复制代码

复制代码

浮生若梦~~~ · 发表于 2024-3-27 17:05

=VSTACK(A1:C1,FILTER(A2:C10,MAP(C2:C10,LAMBDA(x,MAX(IF(A2:A10=OFFSET(x,,-2),C2:C10))=x))))

		自动登录	找回密码
密码			免费注册

[求助] 请教公式如何获取各个分类中的最大值？