通过四个已知条件，去查找数据

2001927f · 发表于 2024-3-27 09:52

在“18版砼配合比”表格内的B\C\D\E列数据是查找已知条件，F~O列的数据是需要查找的数据基础。

在“混凝土成本”表格内通过录入已知的一些信息（黄色背景部分的内容），去另外一个表格内查询数据。

副本副本20240327.rar (55.23 KB, 下载次数: 15)

boyuanoffice · 发表于 2024-3-27 10:25

本帖最后由 boyuanoffice 于 2024-3-27 20:52 编辑

F6右拉:

=IFNA(XLOOKUP(CONCAT($B$6:$E$6),'18版砼配合比'!$B$3:$B$999&'18版砼配合比'!$C$3:$C$999&'18版砼配合比'!$D$3:$D$999&'18版砼配合比'!$E$3:$E$999,'18版砼配合比'!F$3:F$999),"")

复制代码

袁勇 · 发表于 2024-3-27 10:38

？？

=IFERROR(LOOKUP(1,0/(MMULT(('18版砼配合比'!$B$3:$E$107=$B6:$E6)*1,{1;1;1;1})=4),'18版砼配合比'!F$3:F$107),"")

复制代码

2001927f · 发表于 2024-3-27 20:30

boyuanoffice 发表于 2024-3-27 10:25
F6右拉:

代码拷贝进去后，是错误提示！

2001927f · 发表于 2024-3-27 20:33

袁勇发表于 2024-3-27 10:38
？？

这个代码只能针对单位进行查询，后面的数据无法体现出来正确数据！

2001927f · 发表于 2024-3-27 20:47

=SUMIFS(OFFSET('18版砼配合比'!$A:$A,,MATCH(G$2,'18版砼配合比'!$1:$1,)-1),'18版砼配合比'!$B:$B,$B6,'18版砼配合比'!$C:$C,$C6,'18版砼配合比'!$D:$D,$D6&"",'18版砼配合比'!$E:$E,$E6&"")

复制代码

目前我使用的这个代码，但是还是不太理想，目前在“混凝土成本”表格的里面的下拉菜单内容重复地方太多，能否根据“18版砼配合比”的B\C\D\E列内容参照一、二、三、四级菜单，在“混凝土成本”黄色背景地方调整称为四级下拉菜单呢？

boyuanoffice · 发表于 2024-3-27 20:48

2001927f 发表于 2024-3-27 20:30
代码拷贝进去后，是错误提示！

把F6的数据验证去掉

2001927f · 发表于 2024-3-27 20:51

本帖最后由 2001927f 于 2024-3-27 20:53 编辑

boyuanoffice 发表于 2024-3-27 20:48
把F6的数据验证去掉

不太明白您说的意思，能不能在简单一些啊？

boyuanoffice · 发表于 2024-3-27 20:57

本帖最后由 boyuanoffice 于 2024-3-28 09:59 编辑

这是一个多级联动下拉列表的:

副本20240328.7z (26.8 KB, 下载次数: 6)

yellowhawk · 发表于 2024-3-28 10:38

=FILTER('18版砼配合比'!$F$3:$P$107,('18版砼配合比'!$B$3:$B$107=B6)*('18版砼配合比'!$C$3:$C$107=C6)*('18版砼配合比'!$D$3:$D$107=D6)*('18版砼配合比'!$E$3:$E$107=E6))
经过测试，你的四个条件符合的没有数据
面两个条件符合的有一条，
多少条件你自己可以删减

		自动登录	找回密码
密码			免费注册

[求助] 通过四个已知条件，去查找数据