如何根据不规则数据进行求和？非常多的解决方法。

柳絮飘飘 · 发表于 2024-3-26 08:15

本帖最后由柳絮飘飘于 2024-3-26 11:14 编辑

问题：姓名列有单个的，也有使用“/”分割的。如何对各人出现的不同次数进行求和。
看了很多热心网友的解答，每一种解法我都尝试了。非常感谢热心的各种网友，最后还借助了chatgpt查了一种解法（16楼）。
其实我的应用场景是做项目管理的甘特图，同一项工作任务可能同时有2-3个人同时负责，需要统计出每个人的工作负荷。
数据如下：

求和：

如何求和.7z (7.84 KB, 下载次数: 19)

jivy1212 · 发表于 2024-3-26 08:19

=SUMPRODUCT((1-ISERR(FIND("/"&D4&"","/"&$A$2:$A$6&"/")))*$B$2:$B$6)

复制代码

swl4561255 · 发表于 2024-3-26 08:19

=SUMIF(A$2:A$6,"*"&D4&"*",B$2:B$6)

复制代码

我走我流 · 发表于 2024-3-26 08:21

这样? =SUMPRODUCT((1-ISERR(FIND("/"&D4&"/","/"&$A$2:$A$6&"/")))/(MMULT(LEN(SUBSTITUTE($A$2:$A$6,{"","/"},)),{1;-1})+1),$B$2:$B$6)

quqiyuan · 发表于 2024-3-26 08:23

=SUMPRODUCT($B$2:$B$6/(LEN($A$2:$A$6)-LEN(SUBSTITUTE($A$2:$A$6,"/",))+1)*ISNUMBER(FIND(D4,$A$2:$A$6)))

复制代码

袁勇 · 发表于 2024-3-26 08:40

如果是分摊：=SUMPRODUCT(ISNUMBER(FIND("/"&D4&"/","/"&A$2:A$6&"/"))*B$2:B$6/(LEN(A$2:A$6)-LEN(SUBSTITUTE(A$2:A$6,"/",))+1))

如果不分摊：=SUMPRODUCT(ISNUMBER(FIND("/"&D4&"/","/"&A$2:A$6&"/"))*B$2:B$6)

leepoison · 发表于 2024-3-26 09:01

SUM(FILTER($B$2:$B$6,IFERROR(FIND(D4,$A$2:$A$6),0)>0))

柳絮飘飘 · 发表于 2024-3-26 09:42

jivy1212 发表于 2024-3-26 08:19

测试，公式可行，非常感谢！

柳絮飘飘 · 发表于 2024-3-26 09:44

swl4561255 发表于 2024-3-26 08:19

测试，公式可行，谢谢！

柳絮飘飘 · 发表于 2024-3-26 09:45

我走我流发表于 2024-3-26 08:21
这样? =SUMPRODUCT((1-ISERR(FIND("/"&D4&"/","/"&$A$2:$A$6&"/")))/(MMULT(LEN(SUBSTITUTE($A$2:$A$6,{"", ...

公式错误，

2,
5.5
3.5

		自动登录	找回密码
密码			免费注册

[已解决] 如何根据不规则数据进行求和？非常多的解决方法。