求助，如何根据给出的列编号，统计满足条件行的列求和

tangteng822

如上图所示：
H4需要根据 E4中的型号去统计列编号1~15+17+19（有的编号只有3个，如1~15+25）的工程量
需要在表2中查找SJC29151S对应的行，然后再去查找编号1~15+17+19的列，然后汇总。

K2也是一样的，根据E4中的型号去统计列编号62+75（有的编号只有1个，如65）的工程量

不知道各位老大有什么解决方法没有。

先谢谢各位大佬了。
根据编号列求和.zip (16.97 KB, 下载次数: 6)

2024-3-25 22:24 上传

点击文件名下载附件

tangteng822

不知道有大佬能解决吗， 主要是1~15，后面还加了17+19 ，，有的时候后面只加一个，有的时候要加2个，3个。

kwinawyeth

这个只能VBA解决了，简单写了几句代码，点击按钮【计算重量】就可以了

1. Sub JiSuanZhongLiang() '计算重量
   
2. 
   
3.     Dim i As Long, j As Integer, k As Integer
   
4.     Dim m As Integer
   
5.     Dim zRow As Long
   
6.     Dim benTi, benZhong As Double
   
7.     Dim jiaoTi, jiaoZhong As Double
   
8.    
   
9.     zRow = Sheets("型号重量表").Cells(Sheets("型号重量表").Rows.Count, 1).End(xlUp).Row
   
10. 
    
11.     For j = 4 To 19 Step 4 '循环明细表中每个型号
    
12.    
    
13.         For i = 2 To zRow
    
14.             If Cells(j, 5) = Sheets("型号重量表").Cells(i, 1) Then
    
15.             
    
16.                 '计算本体重量
    
17.                 benZhong = 0
    
18.                 benTi = FenjieBentiBianhao(Cells(j, 7))
    
19.                 For k = LBound(benTi) To UBound(benTi)
    
20.                     benZhong = benZhong + Sheets("型号重量表").Cells(i, 1 + benTi(k))
    
21.                 Next k
    
22.                 Cells(j, 8) = benZhong
    
23.                
    
24.                 '计算脚重
    
25.                 For m = 0 To 3
    
26.                     jiaoZhong = 0
    
27.                     jiaoTi = FenjieBentiBianhao(Cells(j + m, 10))
    
28.                     For k = LBound(jiaoTi) To UBound(jiaoTi)
    
29.                         jiaoZhong = jiaoZhong + Sheets("型号重量表").Cells(i, 1 + jiaoTi(k))
    
30.                     Next k
    
31.                     
    
32.                     Cells(j + m, 11) = jiaoZhong
    
33.                     
    
34.                 Next m
    
35.                
    
36.                 Exit For
    
37.             End If
    
38.             
    
39.         Next i
    
40. 
    
41.     Next j
    
42. 
    
43. End Sub
    
44. 
    
45. Private Function FenjieBentiBianhao(bianHao As String)  '分解本体编号
    
46. 
    
47.     '1~15+17+19
    
48.     Dim bArr, lianXu
    
49.     Dim result() As Integer, r As Integer
    
50.     Dim i As Integer, j As Integer
    
51.    
    
52.     bArr = Split(bianHao, "+")
    
53.    
    
54.     For i = LBound(bArr) To UBound(bArr)
    
55.         
    
56.         If InStr(bArr(i), "~") > 1 Then '分解1至15
    
57.         
    
58.             lianXu = Split(bArr(i), "~")
    
59.             For j = Int(lianXu(0)) To Int(lianXu(1))
    
60.                 r = r + 1
    
61.                 ReDim Preserve result(1 To r)
    
62.                 result(r) = j
    
63.             Next j
    
64.             
    
65.         Else '分解单个整数
    
66.             r = r + 1
    
67.             ReDim Preserve result(1 To r)
    
68.             result(r) = Int(bArr(i))
    
69.         End If
    
70.     Next i
    
71.    
    
72.     FenjieBentiBianhao = result
    
73.    
    
74. End Function
    

复制代码

博爱风雨同舟

=LET(A,TOROW(HSTACK(ROW(INDIRECT(SUBSTITUTE(TEXTBEFORE(G4,"+"),"~",":"))),TEXT({1;-1}%,SUBSTITUTE(TEXTAFTER(G4,"+"),"+",";"))/1),2,1),SUMPRODUCT(IFERROR((SIGN(MATCH(型号重量表!$B$1:$DQ$1,A,)))*(型号重量表!$B$2:$DQ$41)*(型号重量表!$A$2:$A$41=E4),)))