Excel公式，重复单列n次

eh30040922

需求
用1个Excel公式，复制A3:A9为n次（n为正整数），n就是单元格B2的值
处理用REDUCE+HSTACK，还有别的思路吗？
各位前辈，八仙过海，完美解决，晚点整理一下发出来，感谢各位

整理的公式如下，说明
B1为需要重复的次数
A3:A9为需要重复的列区域


公式1，REDUCE+SEQUENCE+HSTACK=LET(db,A3:A9,REDUCE(db,SEQUENCE(B1-1),LAMBDA(s,t,HSTACK(s,db))))

公式2，CHOOSECOLS+EXPAND
=LET(db,A3:A9,CHOOSECOLS(db,EXPAND(1,,B1,1)))

公式3，CHOOSECOLS+SEQUENCE
=CHOOSECOLS(A3:A9,SEQUENCE(,B1,1,0))

公式4，IFNA+EXPAND
=LET(db,A3:A9,IFNA(EXPAND(db,,B1),db))

公式5，IF+SEQUENCE
=IF(SEQUENCE(,B1,,)>0,A3:A9)

公式6，IF+SEQUENCE
=(IF(SEQUENCE(,B1),A3:A9))

公式7，TRANSPOSE+TEXTSPLIT+REPT+TEXTJOIN
=TRANSPOSE(TEXTSPLIT(REPT(TEXTJOIN("，",,A3:A9)&"。",B1),"，","。",1))

公式8，DROP+REDUCE+VSTACK+EXPAND
=DROP(REDUCE("",A3:A9,LAMBDA(x,y,VSTACK(x,EXPAND(y,,B1,y)))),1)

公式9，非数组公式，OFFSET+ROW+COLUMN
=OFFSET($A$3,ROW(A1)-1,N(COLUMN(A1)<=$B$1)-1)

quqiyuan

这样吗？下拉右拉
=OFFSET($A$3,ROW(A1)-1,N(COLUMN(A1)<=$B$1)-1)

mykitami

=IFNA(EXPAND(A3:A9,,B1),A3:A9)

mykitami

=IF(SEQUENCE(,B1)>0,A3:A9)

祝洪忠-

=TOCOL(IF(SEQUENCE(,B2),A3:A9))

boyuanoffice

=CHOOSECOLS(A3:A9,SEQUENCE(,B1,1,0))

橒♂蝣

=TRANSPOSE(TEXTSPLIT(REPT(TEXTJOIN(",",1,A3:A9)&".",9),",",".",1))

橒♂蝣

=DROP(REDUCE("",A3:A9,LAMBDA(x,y,VSTACK(x,EXPAND(y,,9,y)))),1)

Excel地板砖

1. =OFFSET($A$3,ROW(A1)-1,,)

复制代码

swl4561255

右拉下拉出现空为止

1. =OFFSET($A$3,ROW(1:1)-1,INT((COLUMN(A:A)-1)/8),)&""

复制代码