最少交换次数题目（奖励发放完毕）

cinlo · 发表于 2024-3-24 14:53

静听溪流发表于 2024-3-24 10:50
嗯是的昨天群里问了说不用考虑数值类型

这两天烧糊了，没看群

cinlo · 发表于 2024-3-24 14:56

本帖最后由 cinlo 于 2024-3-24 15:37 编辑

知道怎么处理VSTACK了：

=ROWS(UNIQUE(SCAN(1&A2,ROW($1:12),LAMBDA(x,y,SUBSTITUTE(x,MID(1&B2,y,1),MID(x,y,1))))))-1

复制代码

xlllw203 · 发表于 2024-3-24 16:46

本帖最后由 xlllw203 于 2024-3-24 16:48 编辑

=COUNT(--TEXTSPLIT(REDUCE(A2,SEQUENCE(LEN(A2)),LAMBDA(x,y,LET(a,MID(x,y,1),b,MID(B2,y,1),IF(a<>b,SUBSTITUTE(x,b,a)&";"&y,x)))),";"))

复制代码

渡渡orz · 发表于 2024-3-26 10:16

shaowu459 · 发表于 2024-3-26 10:33

xlllw203 发表于 2024-3-24 16:46

两个字符串分别为文本型的“1”时公式返回结果不对，公式需调整

xlllw203 · 发表于 2024-3-26 11:06

本帖最后由 xlllw203 于 2024-3-26 11:10 编辑

shaowu459 发表于 2024-3-26 10:33
两个字符串分别为文本型的“1”时公式返回结果不对，公式需调整

=COUNTA(TEXTSPLIT(REDUCE(A2,SEQUENCE(LEN(A2)),LAMBDA(x,y,LET(a,MID(x,y,1),b,MID(B2,y,1),IF(a<>b,SUBSTITUTE(x,b,a)&";"&y,x)))),";"))-1

复制代码

这样调整了一下。其实这个是一开始写出来的，后来为了省的写-1，所以改成了之前的那个。
COUNT判断情况下，当源字符为数字时，就会把源字符本身也算上，导致多计数1

realdoraemon · 发表于 2024-3-28 08:59

本帖最后由 realdoraemon 于 2024-3-28 09:06 编辑

用了递归函数能算个方案吗？

名称m=LAMBDA(p,q,LET(n,LEN(p)-1,a,LEFT(p,1),b,LEFT(q,1),IF(n=0,0,1-(a=b)+m(RIGHT(SUBSTITUTE(p,b,a),n),RIGHT(q,n)))))

公式=m(A2,B2)

shaowu459 · 发表于 2024-3-28 09:14

realdoraemon 发表于 2024-3-28 08:59
用了递归函数能算个方案吗？

名称m=LAMBDA(p,q,LET(n,LEN(p)-1,a,LEFT(p,1),b,LEFT(q,1),IF(n=0,0,1-( ...

可以。为了保证统一口径，改成单元格递归公式：

=LET(m,LAMBDA(m,p,q,LET(n,LEN(p)-1,a,LEFT(p,1),b,LEFT(q,1),IF(n=0,0,1-(a=b)+m(m,RIGHT(SUBSTITUTE(p,b,a),n),RIGHT(q,n))))),m(m,A2,B2))

复制代码

zhentu · 发表于 2024-3-28 11:15

可以不用新函数吗，wps忘不了。。

realdoraemon · 发表于 2024-3-28 13:35

写了一个不知道有没有和别人重复

=LEN(REDUCE(A2,SEQUENCE(LEN(A2),,LEN(A2),-1),LAMBDA(s,n,LET(a,MID(s,n,1),b,MID(B2,n,1),LEFT(SUBSTITUTE(s,b,a),LEN(s)-(a=b))))))

		自动登录	找回密码
密码			免费注册

[讨论] 最少交换次数题目（奖励发放完毕）

评分

评分

评分