LET里使用COUNTIF报错

boyuanoffice

试试这个:

1. =LET(
   
2.   x,SEQUENCE(LEN(B2)),
   
3.   y,MID(B2,x,1),
   
4.   z,TEXTSPLIT(SUBSTITUTE(SUBSTITUTE(CONCAT(y&SCAN(0,x,LAMBDA(a,b,REPT("/",-1^SUM((x<b)*(y="/"))=1)))),"+/","+"),"r/","r"),"/",,1),
   
5.   c,IF(LEN(z)=1,z,"/"&z&"/"),
   
6.   d,TRANSPOSE(UNIQUE(c,1)),
   
7.   BYROW(--EXACT(d,c),LAMBDA(e,SUM(e)))
   
8. )

复制代码

咔咔乱坠

以2楼数据为例，拆分，计数，去重

1. =LET(a,TEXTSPLIT("AAT/i88/CGT/i88/GGAAACGGGA/i88/AATTTCAGCT",,"/"),UNIQUE(IF({1,0},a,MMULT(N(TOROW(a)=a),SEQUENCE(ROWS(a))^0))))

复制代码

Qinnuomi

boyuanoffice 发表于 2024-3-20 08:16
试试这个:

这个可以，谢谢大佬。

Qinnuomi

咔咔乱坠 发表于 2024-3-20 10:42
以2楼数据为例，拆分，计数，去重

这个拆分的逻辑不对，谢谢了。

Qinnuomi

boyuanoffice 发表于 2024-3-20 08:16
试试这个:

以5_d的数据为查询条件，我需要在一个超级表中找到对应的数据，由于数据有重复性，就是一对多的，目前考虑的是用filter筛选，通过match找到对应列，再把数据用choosecols挑出来，这样的数据处理在let中也是不能使用的。由于涉及公司保密信息，没办法上表。
我再简单描述下，去重后的信息，我需要去超级表里查找对应的行，然后筛选其中的两个列，再把数据汇总，由于不完全的一对一，这个数据有什么办法可以处理吗？

boyuanoffice

可以用 ISNUMBER(FIND()) 的结果作为FILTER()的筛选条件, 直接FILTER所需要的两个列, 貌似不用再CHOOSECOLS了吧.

Qinnuomi

boyuanoffice 发表于 2024-3-20 12:20
可以用 ISNUMBER(FIND()) 的结果作为FILTER()的筛选条件, 直接FILTER所需要的两个列, 貌似不用再CHOOSECOLS ...

要去filer的数据是这样的，ISNUMBER(FIND()) 不能作为筛选条件，因为判定条件的列有A也有 *A*这种 ，

Qinnuomi

Qinnuomi 发表于 2024-3-20 18:56
要去filer的数据是这样的，ISNUMBER(FIND()) 不能作为筛选条件，因为判定条件的列有A也有 *A*这种 ，

要以具体碱基这列作为条件，返回物料编码及通过MATCH查询的对应列的数值

Qinnuomi

=IF(A1="","",SUM(LET(
   x,SEQUENCE(LEN(数据计算!B2)),
   y,MID(数据计算!B2,x,1),
   z,TEXTSPLIT(SUBSTITUTE(SUBSTITUTE(CONCAT(y&SCAN(0,x,LAMBDA(a,b,REPT("/",-1^SUM((x<b)*(y="/"))=1)))),"+/","+"),"r/","r"),"/",,1),
   c,IF(LEN(z)=1,z,"/"&z&"/"),
   d,TRANSPOSE(UNIQUE(c,1)),
   f,BYROW(--EXACT(d,c),LAMBDA(e,SUM(e))),
   h,TEXTSPLIT(TEXTJOIN(",",TRUE,BYROW(d,LAMBDA(r,TEXTJOIN(",",,FILTER(OFFSET(BOM[[#全部],[物料编码]],,MATCH(数据计算!F2,BOM[[#标题],[物料编码]:[20Umol]],0)-1),r=BOM[[#全部],[具体修饰]]))))),",")*1,
   g,BYROW(d,LAMBDA(r,TEXTJOIN(",",,COUNT(FILTER(OFFSET(BOM[[#全部],[物料编码]],,MATCH(数据计算!F2,BOM[[#标题],[物料编码]:[20Umol]],0)-1),r=BOM[[#全部],[具体修饰]])*1)))),
   i,TEXTSPLIT(CONCAT(REPT(f&",",g)),",",,TRUE)*1,
   j,XLOOKUP(TEXTSPLIT(A1,",",,TRUE),物料单价!A:A,物料单价!C:C)*1,
   i*j*h
   )))
已经解决了，谢谢各位大佬的帮忙