word图片导出问题

udnovo

求助大神。
有多个word文档，有的里面有图片，有的没有，想批量导出所有word中的图片，并以文档名来命名图片，请问怎么实现。


还有1个word文档合并的问题，多个word文档合并，为什么有些文档出错合并不了，文件是没有问题的，能正常打开。

3190496160

没有附件，说再多也是没用的，上传附件

gwjkkkkk

Option Explicit
Sub test0() '导图片
    Dim strFileName$, strPath$, n&, strDocName$, shp As Shape, inLineShp As InlineShape
   
    Application.ScreenUpdating = False
    strPath = ThisDocument.Path & "\"
    strFileName = Dir(strPath & "*.doc*")
   
    Do Until strFileName = ""
        If strFileName <> ThisDocument.Name Then
            With Documents.Open(strPath & strFileName)
                For Each shp In .Shapes
                    If shp.Type = msoPicture Then shp.ConvertToInlineShape
                Next
                strDocName = Left(strFileName, InStrRev(strFileName, ".") - 1)
                n = 0
                For Each inLineShp In .InlineShapes
                    n = n + 1
                    Call ToSaveImg(inLineShp, strPath & strDocName & "-" & n & ".png")
                Next
                .Close False
            End With
        End If
        strFileName = Dir
    Loop
   
    Application.ScreenUpdating = True
    Beep
End Sub
Sub test1() '合并文档
    Dim strFileName$, strPath$, strSaveName$
  
    Application.ScreenUpdating = False
    strPath = ThisDocument.Path & "\"
    strFileName = Dir(strPath & "*.doc*")
   
    With Documents.Add
        strSaveName = strPath & "合并"
        Do Until strFileName = ""
            If strFileName <> ThisDocument.Name Then
                With Documents.Open(strPath & strFileName)
                    .Content.Copy
                    .Close False
                End With
                Selection.Paste
            End If
            strFileName = Dir
        Loop
        .SaveAs strSaveName
        .Close
    End With

    Application.ScreenUpdating = True
    Beep
End Sub
Function ToSaveImg(ByVal objShp As InlineShape, ByVal strFullPath As String)
    Const TAG_S = "<pkg:binaryData>"
    Const TAGE = "</pkg:binaryData>"
    Dim objNode As Object, IngStart&, IngEnd&, bytImage() As Byte, strXML$, rngShp As Range

    strXML = objShp.Range.WordOpenXML
    IngStart = InStr(strXML, TAG_S)
    If IngStart = 0 Then
        MsgBox "没有图片数据"
        Exit Function
    Else
        IngStart = IngStart + Len(TAG_S)
        IngEnd = InStr(IngStart, strXML, TAGE)
        strXML = Mid$(strXML, IngStart, IngEnd - IngStart)
        Set objNode = CreateObject("MSXML2.DOMDocument").createELement("b64")
        objNode.DataType = "bin.base64"
        objNode.Text = strXML
        bytImage = objNode.nodeTypedValue
        Open strFullPath For Binary As #1
        Put #1, 1, bytImage
        Close #1
        Set objNode = Nothing
    End If
End Function

gwjkkkkk

请参考附件。。。

常扬帆

下面这种能导出吗？图片是浮于文字上面的。我用您的导出时，出现“没有图片数据”。谢谢您先！

udnovo

gwjkkkkk 发表于 2024-3-21 18:15
Option Explicit
Sub test0() '导图片
    Dim strFileName$, strPath$, n&, strDocName$, shp As Shap ...

感谢大神，试了一下，导出图片可以，合并文档的时候提示出错了

gwjkkkkk

udnovo 发表于 2024-3-24 09:06
感谢大神，试了一下，导出图片可以，合并文档的时候提示出错了

我测试没有问题啊，不知道 是否版本问题。。。

gwjkkkkk

常扬帆 发表于 2024-3-24 08:01
下面这种能导出吗？图片是浮于文字上面的。我用您的导出时，出现“没有图片数据”。谢谢您先！

试试。。。

常扬帆

gwjkkkkk 发表于 2024-3-24 12:23
试试。。。

示例可以，大文件不行，大文件结果还是“没有图片数据”。

zhanglei1371

常扬帆 发表于 2024-3-24 16:48
示例可以，大文件不行，大文件结果还是“没有图片数据”。

那你上传个大文件试试