表格转换想一步到位

jylai

附件涂颜色从那里到那里，由于A列跟B列有重覆，去重覆
从表1到表2想一步到位

miaojohn45

1. =TEXTSPLIT(TEXTJOIN(";",,BYROW(GROUPBY(A2:B13,C2:C13,LAMBDA(x,TEXTJOIN(",",,x)),,0),LAMBDA(x,TEXTJOIN(",",,x)))),",",";",,,"")

复制代码

jylai

老师我的版本已经是 365 V2402了，为舍出现  #NAME?

老师找到原因了，我 365函数没有这个GROUPBY所以不认识，还有别的方法吗？

咔咔乱坠

jylai 发表于 2024-3-17 09:19
老师我的版本已经是 365 V2402了，为舍出现  #NAME?

老师找到原因了，我 365函数没有这个GROUPBY所以不 ...

hh，因为不是beat版365
一般的365可以用这条

1. =LET(a,UNIQUE(A2:B13),IFNA(DROP(REDUCE(0,SEQUENCE(ROWS(a)),LAMBDA(x,y,VSTACK(x,LET(b,DROP(TAKE(a,y),y-1),TOROW(HSTACK(b,FILTER(C2:C13,A2:A13&B2:B13=CONCAT(b))),3))))),1),""))

复制代码

稍作简化，但是整列引用

1. =LET(萝,UNIQUE(A2:B13),IFNA(DROP(REDUCE(0,SEQUENCE(ROWS(萝)),LAMBDA(x,y,VSTACK(x,LET(莉,INDEX(萝,y),TOROW(HSTACK(莉,FILTER(C:C,A:A&B:B=CONCAT(莉))),3))))),1),""))

复制代码

jylai

咔咔乱坠 发表于 2024-3-17 09:34
hh，因为不是beat版365
一般的365可以用这条

老师还是您牛，太棒了，感谢您

无关岁月

1. =HSTACK(UNIQUE(A2:B13),TEXTSPLIT(TEXTJOIN("/",,TAKE(GROUPBY(A2:B13,C2:C13,ARRAYTOTEXT,0,0),,-1)),",","/",,,""))

复制代码

cyh3230

这个用PQ，不用写什么函数就能实现用函数感觉有些麻烦了

1. =TEXTSPLIT(
   
2.     TEXTJOIN(
   
3.         "+",
   
4.         1,
   
5.         MAP(
   
6.             UNIQUE(A2:A13 & "-" & B2:B13),
   
7.             LAMBDA(x,
   
8.                 x & "-" &
   
9.                     TEXTJOIN(
   
10.                         "-",
    
11.                         1,
    
12.                         FILTER(
    
13.                             C2:C13,
    
14.                             A2:A13 & "-" &
    
15.                                 B2:B13 = x
    
16.                         )
    
17.                     )
    
18.             )
    
19.         )
    
20.     ),
    
21.     "-",
    
22.     "+",
    
23.     ,
    
24.     ,
    
25.     ""
    
26. )

复制代码