各位大神们，求指教！！！

lǐm7 · 发表于 2024-3-9 15:40

如何将纵列的数据

A A1
B B1
B B2
更改横列的数据
A B
A1 B1
B2

miaojohn45 · 发表于 2024-3-9 15:42

lǐm7 · 发表于 2024-3-9 15:44

miaojohn45 发表于 2024-3-9 15:42

不是转置，横向只有一个B列，B1和B2在它下面

quqiyuan · 发表于 2024-3-9 15:49

第一行
=IFERROR(INDEX($A:$A,SMALL(IF(MATCH($A$1:$A$3,$A:$A,)=ROW($1:$3),ROW($1:$3)),COLUMN(A1))),"")

第二行
=IFERROR(INDEX($B:$B,SMALL(IF(D$1=$A$1:$A$3,ROW($1:$3)),ROW(A1))),"")

lǐm7 · 发表于 2024-3-9 15:57

quqiyuan 发表于 2024-3-9 15:49
第一行
=IFERROR(INDEX($A:$A,SMALL(IF(MATCH($A$1:$A$3,$A:$A,)=ROW($1:$3),ROW($1:$3)),COLUMN(A1))),"" ...

牛掰，公式完全看不懂

祝洪忠- · 发表于 2024-3-9 16:42

D2 输入公式
=UNIQUE(TOROW(A2:A4),1)

D3 输入公式向右复制
=FILTER($B2:$B4,$A2:$A4=D2)

我的城市你来过 · 发表于 2024-3-9 17:05

=DROP(SORT(UNIQUE(IF(LEFT(SORT(TOCOL(TRIM($A$1:$B$4),)),1)=CHAR(64+COLUMN(A$1)),SORT(TOCOL(TRIM($A$1:$B$4),)),""))),1)

miaojohn45 · 发表于 2024-3-9 17:10

本帖最后由 miaojohn45 于 2024-3-9 21:19 编辑

=LET(n,UNIQUE(A1:A3),VSTACK(TOROW(n),DROP(REDUCE("",n,LAMBDA(x,y,IFNA(HSTACK(x,FILTER(B1:B3,A1:A3=y)),""))),,1)))

复制代码

=TRANSPOSE(IFNA(DROP(REDUCE(0,UNIQUE(A1:A3),LAMBDA(X,Y,VSTACK(X,HSTACK(Y,TOROW(UNIQUE(FILTER(B1:B3,A1:A3=Y))))))),1),""))

复制代码

=TRANSPOSE(LET(S,GROUPBY(A1:A3,B1:B3,LAMBDA(X,TOROW(UNIQUE(X))),,0),HSTACK(TAKE(S,,1),IFNA(REDUCE(,DROP(S,,1),VSTACK),""))))

复制代码

mykitami · 发表于 2024-3-9 17:14

本帖最后由 mykitami 于 2024-3-9 17:16 编辑

F1
=TOROW(UNIQUE(A1:A3))
F2
=FILTER($B$1:$B$3,$A$1:$A$3=F1)
右拉

		自动登录	找回密码
密码			免费注册

[已解决] 各位大神们，求指教！！！

评分

评分

评分

评分