多个条件求值的公式

hibari18018 · 发表于 2024-3-4 13:20

求助多个条件求值的公式，自己试了一下lookup+find因为条件比较多不知道怎么写，具体请见附件

solextrade · 发表于 2024-3-4 13:38

=INDEX(CHOOSE({1,2,3,4},"上海",A2&"","北京","行政管理"),TEXT(MATCH(1,FREQUENCY(1,MMULT(COUNTIFS(A2,"*"&{"上海";"上海";"北京";"行政"}&"*",B2,{"A","B","C";"D","E","Z";"*","*","*";"*","*","*"}),{1;1;1})),),"[=5]2;0"))

xlllw203 · 发表于 2024-3-4 13:40

=IF(ISNUMBER(FIND("行政",A2)),"行政管理",IF(ISNUMBER(FIND("北京",A2)),"北京",IF(ISNUMBER(FIND("上海",A2))*OR(B2={"A","B","C"}),"上海",A2)))

复制代码

直接IF到底好了。。。

tmplinshi · 发表于 2024-3-4 13:43

=IFS(
ISNUMBER(FIND("上海", A2)), IFS(
OR(B2 = {"A", "B", "C"}), "上海",
OR(B2 = {"D", "E"}), A2
),
ISNUMBER(FIND("北京", A2)), "北京",
ISNUMBER(FIND("行政处", A2)), "行政管理",
TRUE, A2
)

复制代码

boyuanoffice · 发表于 2024-3-4 13:49

=IFS(ISNUMBER(FIND("上海",A2)*FIND(B2,"ABC")),"上海",ISNUMBER(FIND("北京",A2)),"北京",ISNUMBER(FIND("行政处",A2)),"行政管理",TRUE,A2)

复制代码

tmplinshi · 发表于 2024-3-4 13:55

=IFS(
COUNTIF(A2, "*上海*"), IFS(
OR(B2 = {"A", "B", "C"}), "上海",
OR(B2 = {"D", "E"}), A2
),
COUNTIF(A2, "*北京*"), "北京",
COUNTIF(A2, "*行政处*"), "行政管理",
TRUE, A2
)

复制代码

hibari18018 · 发表于 2024-3-4 13:58

boyuanoffice 发表于 2024-3-4 13:49

这个公式相对来说比较易懂简洁！非常感谢！

hibari18018 · 发表于 2024-3-4 13:59

感谢楼里回复的各位！学到了很多！

hcm19522 · 发表于 2024-3-4 15:09

=CHOOSE(LOOKUP(1,0/FIND({"","行政处","北京","上海"},A2),ROW($1:$4)),A2,"行政管理","北京",IF(ISERR(FIND(B2,"DE")),"上海",A2))

		自动登录	找回密码
密码			免费注册

[求助] 多个条件求值的公式