搜遍了全网都没有，countifs怎么进行多列or逻辑运算？

mochen91 · 发表于 2024-2-23 22:56

本帖最后由 mochen91 于 2024-2-23 22:59 编辑

如图，想实现的效果：
一、统计有效条目数，B列、C列、E列有一个不为空就是有效条目，D列、G列是忽略不计的。
二、当选中或编辑F列的单元格时，使本行的E列和G列高亮。

关于第一个问题在提问前的尝试：

1、首先想到的是countifs+OR，但搜索了几次都没找到方法，网上都是and逻辑的，没有or逻辑的。最接近的是一篇老外的文章，但也是单区域多条件进行的or逻辑运算，多区域相同条件的一篇都没有。
文章地址：https://statorials.org/cn/excel%e8%ae%a1%e7%ae%97%e5%a4%9a%e5%88%97%e7%9a%84%e6%95%b0%e9%87%8f/
2、其次是sumproduct，同样网上都是and逻辑的，没有or逻辑的。

最后无奈只能添加辅助数据，用countif分别进行计算，然后用large选出最大的那个作为最终结果。

关于第二个问题
目前止步于cell（"address"）获取活动单元格地址，卡在了用row()作比较。目前只能F列所在行被选中时高亮，无法精确到F列。

excel新手，已将附件上传，要是能看到详细的公式说明就太好了，谢谢！

tmplinshi · 发表于 2024-2-24 00:20

=LET(
b, B3:B25,
c, C3:C25,
e, E3:E25,
SUM(
N(
(b <> "") + (c <> "") + (e <> "") > 0
)
)
)

复制代码

祝洪忠- · 发表于 2024-2-24 04:58

=COUNT(0/((B3:B25<>"")+(C3:C25<>"")+(E3:E25<>"")))

mykitami · 发表于 2024-2-24 10:21

对于你自己的答案是17，但考虑到现实意义，我感觉19更合理些，当然可能你有其他的特殊考量。
=COUNT(0/(MMULT((B3:E25<>"")*{1,1,0,1},{1;1;1;1})>=1))
啸海老师的>1,我改为>=1，结果也是19

无关岁月 · 发表于 2024-2-23 23:09

=MAX(COUNTIF(OFFSET(B3:B26,,{0,1,3}),"<>"))

复制代码

一烟难禁 · 发表于 2024-2-23 23:25

sumproduct的or逻辑是+，你确定全网都没有？

miaojohn45 · 发表于 2024-2-23 23:35

="有效条目数为："&SUM(N(B:B&C:C&E:E<>""))

啸海 · 发表于 2024-2-23 23:40

=COUNT(0/(MMULT((B3:E25<>"")*{1,1,0,1},{1;1;1;1})>1))

tmplinshi · 发表于 2024-2-24 00:09

一、统计有效条目数，B列、C列、E列有一个不为空就是有效条目

最后无奈只能添加辅助数据，用countif分别进行计算，然后用large选出最大的那个作为最终结果。

这两个逻辑并不匹配。下面截图的例子，按你第一个说法是 7 条有效，按你第二个说法是 5 条有效。

我的城市你来过 · 发表于 2024-2-24 09:33

本帖最后由我的城市你来过于 2024-2-26 19:36 编辑

姓名名称AND计算=MAX(SUBTOTAL(3,OFFSET($B$2:$B$25,,{0,1,3}))-1)

姓名名称OR计算=SUM(IF(B3:B25&$C$3:$C$25<>"",ROW($E$3:$E$25)^0,""))

		自动登录	找回密码
密码			免费注册

[求助] 搜遍了全网都没有，countifs怎么进行多列or逻辑运算？

评分