如何显示abc的排列组合？

leepoison · 发表于 2024-2-23 11:24

本帖最后由 leepoison 于 2024-2-24 08:22 编辑

求解答。

世界客都 · 发表于 2024-2-23 11:32

朋友，能否把你实际需求放上来，就abc组合才6个，枚举就行了，用公式没多大意义的。

Meteor-渣渣 · 发表于 2024-2-23 11:44

miaojohn45 · 发表于 2024-2-23 11:44

=BYROW(INDEX(B1:D1,MID(FILTER(ROW(123:321),MMULT(IFERROR(FIND(COLUMN(A:C),ROW(123:321)),0),{1;1;1})=6),COLUMN(A:C),1)),CONCAT)

mykitami · 发表于 2024-2-23 12:20

本帖最后由 mykitami 于 2024-2-23 12:29 编辑

=BYROW(INDEX(A1:C1,MID(FILTER(ROW(123:321),MMULT(1*ISNUMBER(FIND(SEQUENCE(,3),ROW(123:321))),SEQUENCE(3)^0)=3),COLUMN(A:C),1)),CONCAT)
哈哈，与楼上撞车了

=LET(a,TOCOL(TOCOL(A1:C1&TOCOL(A1:C1))&A1:C1),FILTER(a,MMULT(N(ISNUMBER(FIND(A1:C1,a))),ROW(1:3)^0)=3))

quqiyuan · 发表于 2024-2-23 12:22

像这种用Python调用一下库做一下，方便多了

tmplinshi · 发表于 2024-2-23 14:04

本帖最后由 tmplinshi 于 2024-2-23 14:27 编辑

=LET(
arr, INDEX(A1:C1, 1, {
1, 2, 3;
1, 3, 2;
2, 1, 3;
2, 3, 1;
3, 1, 2;
3, 2, 1
}),
BYROW(arr, LAMBDA(row, CONCAT(row)))
)

复制代码

=LET(
arr, A1:C1,
VSTACK(
CONCAT(INDEX(arr, , {1, 2, 3})),
CONCAT(INDEX(arr, , {1, 3, 2})),
CONCAT(INDEX(arr, , {2, 1, 3})),
CONCAT(INDEX(arr, , {2, 3, 1})),
CONCAT(INDEX(arr, , {3, 1, 2})),
CONCAT(INDEX(arr, , {3, 2, 1}))
)
)

复制代码

		自动登录	找回密码
密码			免费注册

[已解决] 如何显示abc的排列组合？

评分

评分