求个乘车路线公式

tmplinshi

jerrike

=TOROW(VLOOKUP(TAKE(TEXTSPLIT(F10,,"-"),ROWS(TEXTSPLIT(F10,,"-"))-1)&"-"&DROP(TEXTSPLIT(F10,,"-"),1),IF({1,0},$A$2:$A$17&"-"&$B$2:$B$17,$C$2:$C$17),2,))

tmplinshi

Excel 365 可用

1. =LET(
   
2.     array, Sheet1!$A$2:$C$17,
   
3.     filterByCol, LAMBDA(findCol, findVal, FILTER(array, INDEX(array, , findCol) = findVal)),
   
4.     getPath, LAMBDA(self, foundRows, [curPath],
   
5.         REDUCE(
   
6.             "",
   
7.             SEQUENCE(ROWS(foundRows)),
   
8.             LAMBDA(res, i,
   
9.                 LET(
   
10.                     endStation, INDEX(foundRows, i, 2),
    
11.                     roadName,   INDEX(foundRows, i, 3),
    
12.                     nextRows, filterByCol(1, endStation),
    
13.                     fullPath, IF(
    
14.                         NOT(OR(ISERROR(nextRows))),
    
15.                         self(self, nextRows, curPath & "-" & roadName),
    
16.                         curPath & "-" & roadName
    
17.                     ),
    
18.                     res & ";" & fullPath
    
19.                 )
    
20.             )
    
21.         )
    
22.     ),
    
23.     isFirstStation, LAMBDA(row, ISERROR(MATCH(INDEX(row, , 1), INDEX(array, , 2), 0))),
    
24.     result, BYROW(
    
25.         array,
    
26.         LAMBDA(row,
    
27.             IF(isFirstStation(row), getPath(getPath, filterByCol(3, INDEX(row, , 3))), "")
    
28.         )
    
29.     ),
    
30.     IFERROR(TEXTSPLIT(CONCAT(result), "-", ";", TRUE), "")
    
31. )

复制代码

tmplinshi

WPS / EXCLE 可用

1. =LET(
   
2.     array, Sheet1!$A$2:$C$17,
   
3.     filterByCol, LAMBDA(findCol, findVal, FILTER(array, INDEX(array, , findCol) = findVal)),
   
4.     getPath, LAMBDA(self, foundRows, [i], [curPath],
   
5.         LET(
   
6.             i, i + 1,
   
7.             endStation, INDEX(foundRows, i, 2),
   
8.             roadName, INDEX(foundRows, i, 3),
   
9.             nextRows, filterByCol(1, endStation),
   
10.             fullPath, IF(
    
11.                 NOT(OR(ISERROR(nextRows))),
    
12.                 self(self, nextRows, 0, curPath & "-" & roadName),
    
13.                 curPath & "-" & roadName
    
14.             ),
    
15.             IF(
    
16.                 i < ROWS(foundRows),
    
17.                 fullPath & ";" & self(self, foundRows, i, curPath),
    
18.                 fullPath
    
19.             )
    
20.         )
    
21.     ),
    
22.     isFirstStation, LAMBDA(row, ISERROR(MATCH(INDEX(row, , 1), INDEX(array, , 2), 0))),
    
23.     loopRows, LAMBDA(self, [i],
    
24.         LET(
    
25.             i, i + 1,
    
26.             path, if(
    
27.                 isFirstStation(INDEX(array, i,)),
    
28.                 getPath(getPath, filterByCol(3, INDEX(array, i, 3))),
    
29.                 ""
    
30.             ),
    
31.             IF(i < ROWS(array), path & ";" & self(self, i), path)
    
32.         )
    
33.     ),
    
34.     result, loopRows(loopRows),
    
35.     IFERROR(TEXTSPLIT(result, "-", ";", TRUE), "")
    
36. )

复制代码

我的城市你来过

未知路线起始线=TRIM(TEXTSPLIT(TEXTJOIN(" ",,REPT($C$2:$C$17&"-",COUNTIFS($A$2:$A$17,$B$2:$B$17))),,"-"))
未知路线排班线=LET(x,TRIM(TEXTSPLIT(TEXTJOIN("-",,IF(MAX(IF($C$2:$C$17=E6,$B$2:$B$17,""))=$A$2:$A$17,$C$2:$C$17,"")),"-")),IFERROR(INDEX(x,MIN(COUNTA(x),COUNTIF($E$5:$E6,$E6))),""))

咔咔乱坠

咔咔乱坠 发表于 2024-2-18 11:54
递归玩一下
公式管理器
任意单元格

于超人群中学习了不用名称管理器实现递归的办法，将上次方法优化..

1. =LET(fx,LAMBDA(fx,x,IF(@+ISNA(XLOOKUP(@+x,Sheet1!$A$2:$A$17,Sheet1!$B$2:$C$17)),x,VSTACK(x,fx(fx,XLOOKUP(@+x,Sheet1!$A$2:$A$17,Sheet1!$B$2:$C$17))))),IFNA(REDUCE(G9:M9,A2:A17,LAMBDA(j,k,UNIQUE(VSTACK(j,IFERROR(TOROW(DROP(fx(fx,k),,1),3),""))))),""))

复制代码

dy83797465268

A*算法。。。