筛选数据

天涯论剑

例子：判断A列是否为QWLD开头的编码。
A3单元格是编码，判断C3单元格是否为空，为空的话则忽略，A15单元格是编码，对应的C15不为空，则返回这个编码对应的所有子件15，16，17行的所有数据
（G-J列是结果）

祝洪忠-

工作簿000 (2).zip (11.27 KB, 下载次数: 10)

2024-2-9 16:18 上传

点击文件名下载附件

theking_wsz

=FILTER(A3:D25,1-ISNA(MATCH(LOOKUP(ROW(1:23),IF(A3:A25="【子件】","",ROW(1:23)),A3:A25),FILTER(A3:A25,(LEFT(A3:A25,5)="QWLQD")*(C3:C25<>"")),)))

世界客都

还是辅助列来吧
E3输入：=IF(C3="","",IF(A3="【子件】",E2,A3))
下拉
然后F3单元格
=FILTER(A3:D25,E3:E25>"")
即可

世界客都

祝洪忠- 发表于 2024-2-9 16:18

老师新年好啊，怎么这么敬业，年三十还上班呢

quqiyuan

1. =INDEX(A:A,SMALL(IF(LOOKUP(ROW($1:$23),ROW($1:$23)/(IFERROR(SEARCH("QWLQD*",$A$3:$A$25)*($C$3:$C$25<>""),2)<>2),SEARCH("QWLQD*",$A$3:$A$25)*($C$3:$C$25<>"")),ROW($3:$25)),ROW(A1)))

复制代码

下拉右拉

tmplinshi

1. =LET(
   
2.     src, VSTACK(FILTER(A:D, A:A <> ""), "END"),
   
3.     totalRows, ROWS(src),
   
4. 
   
5.     loop, LAMBDA(i, isMatch, LET(
   
6.         a, INDEX(src, i, 1),
   
7.         c, IFNA(INDEX(src, i, 3),),
   
8.         isMatch, OR(
   
9.             AND(LEFT(a, 5) = "QWLQD", c <> ""),
   
10.             AND(isMatch, a = "【子件】")
    
11.         ),
    
12.         line, IF(isMatch, CHOOSEROWS(src, i)),
    
13.         IF(
    
14.             isMatch,
    
15.             IF(i < totalRows, VSTACK(line, loop(i+1, isMatch)), line),
    
16.             IF(i < totalRows, loop(i+1, isMatch))
    
17.         )
    
18.     )),
    
19. 
    
20.     DROP(loop(1,), -1)
    
21. )

复制代码

miaojohn45

=LET(x,SCAN(,A2:A25,LAMBDA(x,y,IF(y="【子件】",x,y))),FILTER(A2:D25,NOT(IFNA(MATCH(x,FILTER(A2:A25,C2:C25=""),),0))))

tmplinshi

1. =LET(
   
2.     src, FILTER(A:D, A:A <> ""),
   
3.     colA, CHOOSECOLS(src, 1),
   
4.     colC, CHOOSECOLS(src, 3),
   
5.     indexes, SEQUENCE(ROWS(src)),
   
6. 
   
7.     mainRows, FILTER(indexes, LEFT(colA,5) = "QWLQD"),
   
8.     mainMatchRows, FILTER(indexes, (LEFT(colA,5) = "QWLQD") * (colC <> "")),
   
9.     groupRows, LOOKUP(indexes, mainRows),
   
10. 
    
11.     b, ISNUMBER(MATCH(groupRows, mainMatchRows, 0)),
    
12.     FILTER(src, b)
    
13. )

复制代码

evluan01

py水个