跳过表格（宏）SkipTable（由 sylun 老师编写）

413191246se · 发表于 2024-2-9 01:35

* 昨早我重写了一段《跳过表格》宏，沾沾自喜！但与本坛大神 sylun 老师以前所写的宏对比测试后发现，sylun 老师写的宏速度是我的宏的 2.5 倍！看来，公文自动排版整体框架还是要用 sylun 老师的。
* 下面是 sylun 老师以前所写的《跳过表格》宏（我略改了一下），仅供各位朋友及新人朋友参考借鉴：
（在应用宏之前，请自行准备两个Word文档，一个是纯文字的；一个是字表混合的（最好有两个表））。
* 排版思路：纯文字文档，全选统一处理；字表混合文档，须将表格当作大田田埂、表前/表间/表后文字区域当作禾苗，即 Range 区域，循环处理即可（有兴趣的朋友们可以参考借鉴我的《公文自动排版》代码）。

Sub TextStyle()
Dim r(), t As Table, n&
With ActiveDocument
ReDim r(.Tables.Count + 1) 'skip table/code by sylun
If .Tables.Count = 0 Then
Set r(1) = .Content
Else
For Each t In .Tables
With t.Rows
.WrapAroundText = False
.Alignment = wdAlignRowCenter
End With
Next
For n = 1 To .Tables.Count
If n = 1 Then
Set r(n) = .Range(0, .Tables(n).Range.Start)
Else
Set r(n) = .Range(.Tables(n - 1).Range.End, .Tables(n).Range.Start)
End If
Next
Set r(n) = .Range(.Tables(n - 1).Range.End, .Content.End)
End If
For n = 1 To UBound(r)
With r(n)
.Select
.Font.Color = wdColorBlue
End With
Next
End With
End Sub

复制代码

zhanglei1371 · 发表于 2024-2-9 12:28

你的2.5分之一的代码也贴出来学习下，感觉不应该差太多

413191246se · 发表于 2024-2-9 19:07

* zhanglei 老师：过年好！合家欢乐！
* 我昨早写的是用 Selection 对象，刚才改为 Range 对象，短一点的文档，速度确实比 sylun 老师的快一点（他 0.04 秒，我 0.02 秒）；但长一点的文档就不行了，还是他的快。究其原因，我写的是逐段扩展，必然不如整片（Range）选取快速。——所以，最终，跳过表格（宏），还是要采用 sylun 老师的代码！
* 但我也把我写的贴上来，大家可以一观：

Sub a1_SkipTable_me_range_optimize()
'0.02s/2024/2/9/18:33
'0.015s
Dim l!: l = Timer
Dim doc As Document
Set doc = ActiveDocument
With doc.Range(0, 0)
Do
Do While Not .Next(4, 1).Information(12)
.MoveEnd 4
If .End = doc.Content.End Then Exit Do
Loop
.Font.ColorIndex = wdBlue
.Start = .End
If .End = doc.Content.End - 1 Then Exit Do
If .Information(12) Then .Start = .Tables(1).Range.End
Loop
End With
MsgBox Timer - l
End Sub

复制代码

gwjkkkkk · 发表于 2024-2-9 20:18

谢谢楼主分享。。。

413191246se · 发表于 2024-2-10 10:41

* 祝 gwjkkkkk 老师，及论坛所有朋友们：过年好！新年好！春节快乐！合家欢乐！身体健康！万事如意！

wdpfox · 发表于 2024-2-10 14:22

Se 老师，新年好。
图中所圈的是否改为：r(n+1)?

413191246se · 发表于 2024-2-10 21:08

本帖最后由 413191246se 于 2024-2-10 21:11 编辑

wdpfox 过年好！——不要改！sylun 老师的代码经测试是完全正确的！说实话，虽然我也不知道 n=3 是怎么来的！——如果你改了，你可以测一下，看看 r(1)、r(2)、r(3) 区域（range）经 Select 后，是不是正确。

排版思路：如果是纯文本，则整个文档就是一个 Range（区域）；如果是字表混合文档，则表格如田埂，文字区域（表前、表中、表后）分别是 Range1、Range2、Range3，只要对这几个区域（Range）循环处理即可。

wdpfox · 发表于 2024-2-22 14:45

明白了，是跳出for循环后，n的值自动+1

文化属性666 · 发表于 2024-3-13 11:19

不自动排版情况下，单独执行这段代码有什么用？

413191246se · 发表于 2024-3-21 02:16

* 楼上朋友，你好！——这段代码仅仅是说明，无论是纯文本（无表格）排版，还是字表混合排版，绕过表格，仅排版文字区域，是一种排版思路；因为，表格排版不太好办。
* 如果哪位朋友也想自己编辑排版程序，可以借鉴此代码，算是一种算法、架构，是公文自动排版的基础。

		自动登录	找回密码
密码			免费注册

[分享] 跳过表格（宏）SkipTable（由 sylun 老师编写）