请教高人关于Excel表如何使用公式用零填充IP地址补齐三位数显示的问题

pgp5866 · 发表于 2024-2-9 10:33

这是低版本的
=MID(CONCAT(TEXT(TRIM(MID(SUBSTITUTE(C6,".",REPT(" ",99)),COLUMN(A:D)*99-98,99)),"000")&"."),1,15)

tmplinshi · 发表于 2024-2-9 14:14

=REPLACE(CONCAT("."&RIGHT(SUBSTITUTE(LEFT(C6,FIND("#",SUBSTITUTE(C6&".",".","#",{1;2;3;4}))-1),".","00"),3)),1,1,)

复制代码

数组公式

idiocy · 发表于 2024-2-10 08:04

yellowhawk 发表于 2024-2-9 00:21
这个思路很活

原来如此````
这些公式都是高人写的,
小弟写不来这些公式,
还在学习中.

idiocy · 发表于 2024-2-10 08:06

yellowhawk 发表于 2024-2-9 00:22
这个是最新函数才能用的

原来如此````
小弟在想这个Microsoft Office 软件版本太多了,
公式应该是会有些不一样的,
还是高人厉害啊````

idiocy · 发表于 2024-2-10 08:08

pgp5866 发表于 2024-2-9 10:29
=TEXTJOIN(".",,TEXT(TEXTSPLIT(C6,,"."),"000"))

非常的感谢高人的帮助指教啊,

小弟向高人学习了```

idiocy · 发表于 2024-2-10 08:10

pgp5866 发表于 2024-2-9 10:33
这是低版本的
=MID(CONCAT(TEXT(TRIM(MID(SUBSTITUTE(C6,".",REPT(" ",99)),COLUMN(A:D)*99-98,99)) ...

非常非常的感谢高人的帮助指教啊```

这个区分高低版本的公式小弟要留着收好.

idiocy · 发表于 2024-2-10 08:12

tmplinshi 发表于 2024-2-9 14:14
数组公式

非常的感谢高人的帮助指教啊,

这个数组公式小弟也留着收好,
原来求解的思路有很多啊````

我的城市你来过 · 发表于 2024-2-15 13:32

=TEXTJOIN(".",,TEXT(TRIM(MID(SUBSTITUTE(C6,".",REPT(" ",99)),ROW($A$1:$A$4)*99-98,99)),"000"))

idiocy · 发表于 2024-2-18 17:26

我的城市你来过发表于 2024-2-15 13:32
=TEXTJOIN(".",,TEXT(TRIM(MID(SUBSTITUTE(C6,".",REPT(" ",99)),ROW($A$1:$A$4)*99-98,99)),"000"))

非常的感谢高人的帮助指教啊````

小弟留着收好.

jivy1212 · 发表于 2024-2-19 10:57

本帖最后由 jivy1212 于 2024-2-19 11:35 编辑

=MID(SUBSTITUTE(RMB(NPV(-0.999,-1,-TEXT({"",0,-1,1},""""&SUBSTITUTE(C6,".",""";""")&""""),),),",","."),3,15)

复制代码

如果都是192168开头，那么可以偷下，

=LEFT(C6,8)&TEXT(SUM(TEXT({1,-1}%,SUBSTITUTE(MID(C6,9,66),".",";"))*10^{3,0}),"000!.000")

复制代码

		自动登录	找回密码
密码			免费注册

[已解决] 请教高人关于Excel表如何使用公式用零填充IP地址补齐三位数显示的问题