按要求提取对应的字符

雪姣Jasmine · 发表于 2024-2-1 19:04

B列提取A列中品牌，保留牌前的“英文字母”及“牌”字，其他汉字不保留
C列提取A列中的型号，即型之前的英文字母，其中无型号比较特别，保留
C列提取A列中的原产国，汉字个数可能不定，但是必定带“原产国：”这个特定前缀，其中“：”可能是英文也可能是中文状态。没有原产国的为空。

hxj119 · 发表于 2024-2-1 20:57

本帖最后由 hxj119 于 2024-2-1 21:35 编辑

原产国：
=IFERROR(MID(A2,FIND("原产国",A2)+4,9),"")

hxj119 · 发表于 2024-2-1 21:07

型号：
=TEXTBEFORE(TEXTAFTER(A2,"牌|")&"|","|")

hxj119 · 发表于 2024-2-1 21:14

本帖最后由 hxj119 于 2024-2-1 21:35 编辑

品牌：
=CONCAT(IF(LENB(MID(TEXTAFTER(TEXTBEFORE(A2,"牌|"),"|",-1),ROW($1:$12),1))=2,"",MID(TEXTAFTER(TEXTBEFORE(A2,"牌|"),"|",-1),ROW($1:$12),1)))&"牌"

一烟难禁 · 发表于 2024-2-1 23:35

原产国那里的正则不知道怎么写才能在一个分组中

雪姣Jasmine · 发表于 2024-2-4 18:40

hxj119 发表于 2024-2-1 21:07
型号：
=TEXTBEFORE(TEXTAFTER(A2,"牌|")&"|","|")

06版本的，textbefore和textafter没有。

伊可赛二 · 发表于 2024-2-4 19:18

alan57 · 发表于 2024-2-4 19:48

=IFNA(REDUCE(B1:D1,A2:A8,LAMBDA(s,t,VSTACK(s,LET(_a,TEXTSPLIT(t,,"|",1),_b,MAP({"牌","型","原产国"},LAMBDA(x,TOCOL(INDEX(_a,MATCH(0,0/FIND(x,_a),)),3))),MAP(_b,LAMBDA(x,IF(COUNT(FIND(":",x)),TEXTAFTER(x,":",,,1),MID(x,IFERROR(@SORT(FIND(CHAR(ROW(48:90)),x)),1),99)))))))),"")

复制代码

象山海鲜 · 发表于 2024-3-1 16:32

凑合一个右拉下拉

=IFNA(TRIM(LEFT(SUBSTITUTE(TRIM(SUBSTITUTE(SUBSTITUTE(REPLACE(ASC($A2),1,MATCH(1,0/(ROW($1:$98)<FIND("|",$A2&"|",FIND(INDEX({"牌","型","原产国"},COLUMN(A1)),$A2))-1)/(MMULT(N(MID($A2&-1,ROW($1:$98)+{0,1},1)<"吖"),{1;2})=2)),),"|"," "),":"," "))," ",REPT(" ",99)),99)),"")

复制代码

		自动登录	找回密码
密码			免费注册

[已解决] 按要求提取对应的字符

评分