FILTER排序问题

亚戈888 · 发表于 2024-1-26 17:21

本帖最后由亚戈888 于 2024-1-26 20:10 编辑

希望能按照2221、2221.01、2221.01.01、2221.01.02、2221.02、2221.03排序

qwer401245 · 发表于 2024-1-26 17:28

hxj119 · 发表于 2024-1-26 17:33

本帖最后由 hxj119 于 2024-1-26 17:34 编辑

=SORTBY(UNIQUE(FILTER($A$2:$A$19,$B$2:$B$19="Y")),--LEFT(UNIQUE(FILTER($A$2:$A$19,$B$2:$B$19="Y")),FIND("–",D3#)-1))

良良 · 发表于 2024-1-26 17:34

G3=INDEX(D:D,MOD(SMALL(LEFT(D$3:D$15,FIND("–",D$3:D$15)-1)/1%%+ROW($3:$15),ROW(A1)),100))，三键，下拉。

edwin11891 · 发表于 2024-1-26 18:13

hxj119 发表于 2024-1-26 17:33
=SORTBY(UNIQUE(FILTER($A$2:$A$19,$B$2:$B$19="Y")),--LEFT(UNIQUE(FILTER($A$2:$A$19,$B$2:$B$19="Y")),F ...

稍稍改造一下，脱离D列。WPS最新版可用，MS365可用。
=LET(Ss,UNIQUE(FILTER($A$2:$A$19,$B$2:$B$19="Y")),SORTBY(Ss,--LEFT(Ss,FIND("–",Ss)-1)))

亚戈888 · 发表于 2024-1-26 19:01

学习,提高了,谢谢各位老师!!!

hxj119 · 发表于 2024-1-26 19:49

edwin11891 发表于 2024-1-26 18:13
稍稍改造一下，脱离D列。WPS最新版可用，MS365可用。
=LET(Ss,UNIQUE(FILTER($A$2:$A$19,$B$2:$B$19="Y" ...

漏掉一个，D3#替换成：UNIQUE(FILTER($A$2:$A$19,$B$2:$B$19="Y")) 即可

亚戈888 · 发表于 2024-1-26 20:05

hxj119 发表于 2024-1-26 17:33
=SORTBY(UNIQUE(FILTER($A$2:$A$19,$B$2:$B$19="Y")),--LEFT(UNIQUE(FILTER($A$2:$A$19,$B$2:$B$19="Y")),F ...

增加了三级科目2221.01.01–应交税费–应交增值税–进项税额,排序在最后,咋解决???,文件已重新上传.谢谢!

edwin11891 · 发表于 2024-1-26 20:14

亚戈888 发表于 2024-1-26 20:05
增加了三级科目2221.01.01–应交税费–应交增值税–进项税额,排序在最后,咋解决???,文件已重新上传.谢谢!

用二楼的公式，直接改用文本排序即可。

=LET(Ss,UNIQUE(FILTER($A$2:$A$19,$B$2:$B$19="Y")),SORTBY(Ss,TEXTBEFORE(Ss,"–")))

橒♂蝣 · 发表于 2024-1-26 20:15

=LET(x,IFERROR(TEXTSPLIT(TEXTJOIN(";",1,TEXTBEFORE(D3#,"–")),".",";"),""),
SORTBY(D3#,--INDEX(x,,1),1,INDEX(x,,2),1))

		自动登录	找回密码
密码			免费注册

[已解决] FILTER排序问题