在20个数中，选取10个数的全部组合，用ＶＢＡ怎么写？

薛衡永

在20个数中，选取10个数的全部组合，用ＶＢＡ怎么写？谢谢，

如果是9个或11个或8个等？

shiruiqiang

排列有要求吗？有的或没的写法不同

薛衡永

shiruiqiang 发表于 2024-1-19 17:53
排列有要求吗？有的或没的写法不同

老师你好，从小到大排列。谢谢

gwjkkkkk

Option Explicit
Sub test()
    Dim ar()
    ar = combinArr2(20, 10)
    [A1].CurrentRegion.Clear
    [A1].Resize(UBound(ar), UBound(ar, 2)) = ar
End Sub
Function combinArr2(ByVal m&, ByVal n&)
   
    Dim br&(), vResult, i&, j&, iCount&, iGroup&, vTemp

    iGroup = Application.Combin(m, n)
    ReDim vResult(1 To iGroup, 1 To n)
    ReDim br&(1 To n)
    If n = 1 Then
        For i = 1 To iGroup
            vResult(i, 1) = i
        Next i
        combinArr2 = vResult
        Exit Function
    End If
    For j = 1 To n - 1: br(j) = j: Next
    iCount = 0
   
    Do
        For i = br(n - 1) + 1 To m
            br(n) = i
            iCount = iCount + 1
            For j = 1 To n
                vResult(iCount, j) = br(j)
            Next j
        Next
        If br(n - 1) < br(n) - 1 Then
            br(n - 1) = br(n - 1) + 1
        Else
            For j = n - 2 To 1 Step -1
                If br(j) <> br(j + 1) - 1 Then
                    vTemp = br(j) + 1: br(j) = vTemp: j = j + 1
                    Do Until j = n
                        br(j) = br(j - 1) + 1: j = j + 1
                    Loop
                    Exit For
                End If
            Next
        End If
    Loop Until iCount = iGroup
    combinArr2 = vResult
End Function

gwjkkkkk

数组法，请参考。。。

ykcbf1100

全部组合是指组合中可以有重复数吗？

薛衡永

ykcbf1100 发表于 2024-1-19 19:58
全部组合是指组合中可以有重复数吗？

老师你好：可以有重复的数，

今铭昔

参考：https://club.excelhome.net/forum ... amp;_dsign=6e056603 10楼