Excel导出图片到本地

cidanji

Excel怎么导出图片到本地？

下面我写了 "导出图" 函数，在我的 WPS 里这方法一直正常的，MS office Excel 使用时 导出图片是空的（.past 没粘贴上），有大佬知道为什么吗
是过时了吗
附件可以下载运行试试，看行不行
我的Excel是64位 专业增强2021版的不行

1. Sub png()
   
2. 导出图 Sheet1.Shapes(1), "png"
   
3. End Sub
   
4. Sub jpg()
   
5. 导出图 Sheet1.Shapes(1), "jpg"
   
6. End Sub

复制代码

1. Private Sub 导出图(shp, typ)
   
2. Dim fnam$
   
3. Dim cht As ChartObject
   
4. fnam = ThisWorkbook.Path & "\五角星." & typ
   
5. shp.CopyPicture Appearance:=xlScreen, Format:=xlPicture
   
6. Set cht = ActiveSheet.ChartObjects.Add(0, 0, shp.Width, shp.Height)
   
7. With cht.Chart
   
8.     .ChartArea.Border.LineStyle = xlLineStyleNone
   
9.     If typ = "png" Then .ChartArea.Fill.Visible = False 'typ="png"时透明
   
10.     .Paste
    
11.     .Export fnam ', typ
    
12.     .Parent.Delete
    
13. End With
    
14. CreateObject("Shell.Application").Open fnam & ""
    
15. End Sub

复制代码

perfect131

.select
.Paste
试试

cidanji

perfect131 发表于 2024-1-8 19:23
.select
.Paste
试试

我试下         

cidanji

perfect131 发表于 2024-1-8 19:23
.select
.Paste
试试

感谢大佬！果然先select一下好使了

Private Sub 导出图(shp, typ)
Dim fnam$
Dim cht As ChartObject
fnam = ThisWorkbook.Path & "\五角星." & typ
shp.CopyPicture Appearance:=xlScreen, Format:=xlPicture
Set cht = ActiveSheet.ChartObjects.Add(0, 0, shp.Width, shp.Height)
With cht.Chart
    .ChartArea.Border.LineStyle = xlLineStyleNone
    If typ = "png" Then .ChartArea.Fill.Visible = False 'typ="png"时透明
    .Parent.Select  '新增一句
    .Paste
    .Export fnam ', typ
    .Parent.Delete
End With
CreateObject("Shell.Application").Open fnam & ""
End Sub

cidanji

perfect131 发表于 2024-1-8 19:23
.select
.Paste
试试

谢谢大佬，可以了，select一下再粘好使了