REDUCE函数双循环扩展和堆积套路

shaowu459

在有些涉及结构转换的题目中，经常需要将前一步的数组进行扩展，比如在查找上下级的时候，每一步都要查找当前人员的下级人员堆积在数组右侧。例如，张三有ABC三个下级，那么就张三这一个人就需要扩展成三行：


往下循环，A可能还有A1和A2两个下属，B有B1一个下属，就需要继续扩展：

这种情况下，需要遍历张三的下属ABC，将每个人的下属查到后堆积在数组右侧，结果数组的行数和列数都可能会增加。


这种情况下，使用REDUCE函数双循环可以轻松解决行列扩展问题。本帖以生成多列数据组合为例（非字符串解决方案），介绍双循环的方法。更多的例题，请在我的主题帖里查找，例如BOM展开相关的、上下级相关的。

shaowu459

先看题目要求，左侧是不同系列对应的内容，要求生成右侧的结果，列举每个系列里的内容生成的所有组合。

shaowu459

接下来，先在辅助单元格区域介绍一下主要思路。

第一步，给REDUCE函数的初始值x赋值为第一个系列所有元素。


第二步，要循环B~E列的每一列，以下以循环B列为例。提取B列所有非空元素：


第三步，提取x中的每一行，与B列所有元素横向堆积：




使用IFNA函数屏蔽堆积产生的错误值，将#N/A填充为x中的行。


上述遍历x中的每一行，就需要使用REDUCE函数逐行提取遍历，也就是双层REDUCE函数循环的内层REDUCE函数。循环一次就将已有结果和当前循环生成的结果用VSTACK函数纵向堆积起来。

第四步，循环完B列后，继续循环C列、D列、E列，内层REDUCE函数分别提取x中的每一行与后续系列元素堆积。循环完毕，则返回所有序列元素的全部组合。

shaowu459

解决问题的双循环参考公式如下：

1. =VSTACK(A1:E1,REDUCE(A2:A3,B2:E2,LAMBDA(X,Y,DROP(REDUCE(0,SEQUENCE(ROWS(X)),LAMBDA(S,C,LET(Z,INDEX(X,C,),VSTACK(S,IFNA(HSTACK(Z,TOCOL(OFFSET(Y,,,7),1)),Z))))),1))))

复制代码

shaowu459

上述公式简要说明如下：

=VSTACK(
    A1:E1,    堆积标题行
    REDUCE(   最外层循环，循环值是B~E列
        A2:A3,    外层循环x初始值设定为A系列元素
        B2:E2,    外层循环B~E列
        LAMBDA(X, Y,
            DROP(
                REDUCE(
                    0,
                    SEQUENCE(ROWS(X)),    生成从1到x行数的序列，逐行提取
                    LAMBDA(S, C,
                        LET(
                            Z, INDEX(X, C, ),    逐行提取出x的每一行
                            VSTACK(
                                S,      内层循环的x
                                IFNA(
                                    HSTACK(
                                        Z,     横向堆积x中的当前行和外层循环的系列元素
                                        TOCOL(OFFSET(Y, , , 7), 1)     获取外层循环的那一列非空值
                                    ),
                                    Z   横向堆积错误值屏蔽为x中的当前行
                                )
                            )
                        )
                    )
                ),
                1
            )
        )
    )
)

静听溪流

为大佬点赞

橒♂蝣

楼主厉害，好好学习

scyss

学习新函数！

624134745

为大佬点赞

咔咔乱坠

学习了，感谢超人老师！