请教各位大神关于vba取PDF文本

tspliu

Sub 输出pdf()
Set AcroApp = CreateObject("AcroExch.App")
Set AcroAVDoc = CreateObject("AcroExch.AVDoc")
pdfFolder = "C:\MyPDF.pdf"
s = AcroAVDoc.Open(pdfFolder, "")
Set AcroPDDoc = AcroAVDoc.GetPDDoc
PageNum = AcroPDDoc.GetNumPages
Set Page1 = AcroPDDoc.AcquirePage(0)
'Debug.Print Page1.GetText
'请问这里怎么什么可以debug.print 输出Page1的文本，搜了几个都不行，我现在只能另存为txt再读取Txt
AcroPDDoc.Close
AcroAVDoc.Close (0)
AcroApp.Exit

Set AcroPDDoc = Nothing
Set AcroAVDoc = Nothing
Set AcroApp = Nothing

End Sub

ykcbf1100

Debug.Print只是显示而已

tspliu

ykcbf1100 发表于 2023-9-30 21:15
Debug.Print只是显示而已

  不管是输出还是显示，百度到的 gettex、gettext，gettextcontents等等都提示没有该属性或方法，百度CAcroPDPage有哪些方法和属性又搜不到

bluesky_0

Public Function GetPDFtext(filePath As String, fileName As String)
'读取PDF-解析内容,得到页码
'filePath PD完整地址,例如:D:\OK, fileName 文件名称,例如: a.pdf
Dim AC_PD As New Acrobat.acroPDDoc
Dim AC_Hi As Acrobat.AcroHiliteList
Dim AC_PG As Acrobat.AcroPDPage
Dim Ct_Page As Long
Dim i As Long, j As Long
Dim T_Str As String

Set AC_PD = New Acrobat.acroPDDoc 'PDF文件
Set AC_Hi = New Acrobat.AcroHiliteList 'PDF文本字符
AC_Hi.Add 0, 32767 '限制文本字符个数
            With AC_PD
                markfile = filePath & "\" & fileName  '需要的文件名
                    .Open markfile '打开PDF文件
                        Ct_Page = .GetNumPages '得到PDF文件页数
                        If Ct_Page = -1 Then 'pdf文件页数不对
                            .Close
                            Set AC_PGTxt = Nothing
                            Set AC_PG = Nothing
                            Set AC_Hi = Nothing
                            Set AC_PD = Nothing
                            Exit Function
                        End If
                            Ct_Page = .GetNumPages '得到PDF文件页数
                           
                        For i = 1 To Ct_Page   'PDF第一页开始...
                            T_Str = ""
                            Set AC_PG = .AcquirePage(i - 1) '得到当前页
                            Set AC_PGTxt = AC_PG.CreateWordHilite(AC_Hi) '得到当期文字列表?
                            If Not AC_PGTxt Is Nothing Then
                                With AC_PGTxt
                                    For j = 0 To .GetNumText - 1
                                        T_Str = T_Str & .GetText(j) '获得文本
                                    Next j
                                End With
                            End If
                            ActiveSheet.Range("D" & i + NUM) = i
                            ActiveSheet.Range("E" & i + NUM) = T_Str
                            ActiveSheet.Range("F" & i + NUM) = Application.WorksheetFunction.Clean(WorksheetFunction.Trim(T_Str))
                                                      
                        Next i
                        .Close
            End With
                            Set AC_PGTxt = Nothing
                            Set AC_PG = Nothing
                            Set AC_Hi = Nothing
                            Set AC_PD = Nothing
            
End Function

ykcbf1100

tspliu 发表于 2023-9-30 21:38
不管是输出还是显示，百度到的 gettex、gettext，gettextcontents等等都提示没有该属性或方法，百度 ...

试试这个AI写的代码：

1. Sub ExtractPDFText()
   
2.         Dim filePath As String
   
3.         Dim fileName As String
   
4.         Dim pdfApp As Object
   
5.         Dim pdfDoc As Object
   
6.         Dim pageNumber As Integer
   
7.         Dim pageText As String
   
8. 
   
9.         ' 设置PDF文件路径和文件名
   
10.         filePath = "C:\path\to\your\pdf\file.pdf"
    
11.         fileName = "file.pdf"
    
12. 
    
13.         ' 创建PDF应用对象
    
14.         Set pdfApp = CreateObject("AcroExch.App")
    
15. 
    
16.         ' 打开PDF文件
    
17.         Set pdfDoc = pdfApp.GetActiveDoc(filePath)
    
18. 
    
19.         ' 遍历PDF的每一页
    
20.         For pageNumber = 1 To pdfDoc.GetNumPages
    
21.                 ' 提取当前页的文本
    
22.                 pageText = pdfDoc.GetPageContent(pageNumber)
    
23. 
    
24.                 ' 在此处添加处理文本的代码
    
25. 
    
26.         Next pageNumber
    
27. 
    
28.         ' 关闭PDF文件
    
29.         pdfDoc.Close
    
30. 
    
31.         ' 释放对象
    
32.         Set pdfDoc = Nothing
    
33.         Set pdfApp = Nothing
    
34. 
    
35. End Sub

复制代码

tspliu

tspliu 发表于 2023-9-30 21:38
不管是输出还是显示，百度到的 gettex、gettext，gettextcontents等等都提示没有该属性或方法，百度 ...

多谢大神，今天困扰了我一晚上，终于睡前解决了。

tspliu

Sub 取pdf文本()
Set AcroApp = CreateObject("AcroExch.App")
Set AcroAVDoc = CreateObject("AcroExch.AVDoc")
pdfFolder = "C:\1.pdf"
s = AcroAVDoc.Open(pdfFolder, "")
Set AC_Hi = CreateObject("AcroExch.HiliteList")
AC_Hi.Add 0, 32767
Set AcroPDDoc = AcroAVDoc.GetPDDoc
'PageNum = AcroPDDoc.GetNumPages
Set AC_PG = AcroPDDoc.AcquirePage(0)
Set AC_PGTxt = AC_PG.CreateWordHilite(AC_Hi)
       If Not AC_PGTxt Is Nothing Then
            With AC_PGTxt
                For j = 0 To .GetNumText - 1
                    T_str = T_str & .GetText(j) '获得文本
                Next j
            End With
        End If
Debug.Print T_str
AcroPDDoc.Close
AcroAVDoc.Close 0
AcroApp.Exit
Set AcroPDDoc = Nothing
Set AcroAVDoc = Nothing
Set AcroApp = Nothing
End Sub

tspliu

ykcbf1100 发表于 2023-9-30 21:57
试试这个AI写的代码：

AI的就不用试了，我试了几十次，没一个正确的

yang1992820

tspliu 发表于 2023-9-30 22:41
Sub 取pdf文本()
Set AcroApp = CreateObject("AcroExch.App")
Set AcroAVDoc = CreateObject("AcroExch. ...

请问下我2010版本的Excel一直在 创建AcroEXch.APP这边报无法创建部件，是什么原因呢

tspliu

yang1992820 发表于 2023-10-9 13:45
请问下我2010版本的Excel一直在 创建AcroEXch.APP这边报无法创建部件，是什么原因呢

你安装acrobat了吗