怎么按照表格中的时间区间，汇总对应的数据呢？

GUO143213 · 发表于 2023-7-25 14:48

本帖最后由 GUO143213 于 2023-7-25 16:27 编辑

不好意思，刚刚上传了附件！
请教一下，我要从原始表中筛选出对应时间段的数据，怎么按照表格中的时间区间，汇总对应的数据呢？

hugeinfo · 发表于 2023-7-25 14:51

附件呢

hxj119 · 发表于 2023-7-25 14:55

第一个日期：=LEFT(N1,FIND("-",N1)-1)
第二个日期：=MID(N1,FIND("-",N1)+1,9)

1007890405 · 发表于 2023-7-25 15:00

=TEXT({0.01,-0.01},SUBSTITUTE(A1,"-",";"))
三键数组

博爱风雨同舟 · 发表于 2023-7-25 15:01

--SUBSTITUTE(TEXT({1,-1}%,SUBSTITUTE(B1,"-",";")),".","-")

hugeinfo · 发表于 2023-7-25 15:06

GUO143213 · 发表于 2023-7-25 15:07

hugeinfo 发表于 2023-7-25 14:51
附件呢

刚刚上传了附件

hugeinfo · 发表于 2023-7-25 15:48

GUO143213 发表于 2023-7-25 15:07
刚刚上传了附件

b2==SUMPRODUCT((数据区!$A$2:$A$29>=--TEXT(SUBSTITUTE(INDEX(TEXT({0.01,-0.01},SUBSTITUTE(B1,"-",";")),,1),".","月")&"日","mm月dd日"))*(数据区!$A$2:$A$29<=--TEXT(SUBSTITUTE(INDEX(TEXT({0.01,-0.01},SUBSTITUTE(B1,"-",";")),,2),".","月")&"日","mm月dd日"))*数据区!$B$2:$B$29) 右拉

w4275 · 发表于 2023-7-25 15:56

=NPV(-2,SUMIF(数据区!$A:$A,"<="&SUBSTITUTE(TEXT({1,-1}%,SUBSTITUTE(B$1,"-",";")),".","/")-{1,0},数据区!$B:$B))

复制代码

mykitami · 发表于 2023-7-25 19:14

B２单元格公式：
=LET(_rqs,INDEX(DATE(2023,TEXTBEFORE(TEXTSPLIT(B$1,"-",,TRUE),"."),TEXTAFTER(TEXTSPLIT(B$1,"-",,TRUE),".")),1),
      _rqe,INDEX(DATE(2023,TEXTBEFORE(TEXTSPLIT(B$1,"-",,TRUE),"."),TEXTAFTER(TEXTSPLIT(B$1,"-",,TRUE),".")),2),
      _yrq,数据区!$A$2:$A$29,
      _ysz,数据区!$B$2:$B$29,
         SUM(FILTER(_ysz,(_yrq>=_rqs)*(_yrq<=_rqe)*_ysz)))

		自动登录	找回密码
密码			免费注册

[已解决] 怎么按照表格中的时间区间，汇总对应的数据呢？

评分

评分