想做个Excel的汉字乘法口诀表

dongdonggege

想做个Excel的汉字乘法口诀表，麻烦各位老师。

帮我做下，像这样的，见图，谢谢。

512008404

cai2532

这个必须收藏。

ZHLK

Sub aa()
Dim A(0 To 9)
A(0) = "十"
A(1) = "一"
A(2) = "二"
A(3) = "三"
A(4) = "四"
A(5) = "五"
A(6) = "六"
A(7) = "七"
A(8) = "八"
A(9) = "九"
Columns("A:I").Delete Shift:=xlToLeft
For I = 1 To 9
    For J = 1 To I
    If I * J < 10 Then
        Cells(I, J) = A(J) & A(I) & "得" & A(I * J)
    ElseIf (I * J Mod 10) = 0 Then
        Cells(I, J) = A(J) & A(I) & A(Left(I * J, 1)) & A(0)
    Else
        Cells(I, J) = A(J) & A(I) & A(Left(I * J, 1)) & A(0) & A(Right(I * J, 1))
    End If
    Cells(I, J).Borders.LineStyle = 1
    Next J
Next I
Cells.EntireColumn.AutoFit
   
End Sub

准提部林

二五一十
應是 二五得十 吧!

准提部林

Sub TEST_A1()
Dim Arr(1 To 9, 1 To 9), i%, j%, X$, T$, T1, T2
X = "一二三四五六七八九"
For i = 1 To 9
    T1 = Mid(X, i, 1)
    For j = 1 To 9
        T2 = Mid(X, j, 1)
        T = Replace(Application.Text(i * j, "[DBNum1]"), "一十", "十")
        If Len(T) = 1 Then T = "得" & T
        If j >= i Then Arr(j, i) = T1 & T2 & T
    Next j
Next
[a1].Resize(9, 9) = Arr
End Sub

dongdonggege

准提部林 发表于 2023-7-23 19:09
Sub TEST_A1()
Dim Arr(1 To 9, 1 To 9), i%, j%, X$, T$, T1, T2
X = "一二三四五六七八九"

谢谢老师。我记得汉字乘法口诀表，就是二五一十，建议：不是二五得十。

39660519

这是以前写的

Sub 生成乘法口诀表()
    For A = 1 To 9
        For B = 1 To A
            乘数1 = Application.Text(B, "[DBNUM1]")
            乘数2 = Application.Text(A, "[DBNUM1]")
            C = A * B
            积 = Application.Text(C, "[DBNUM1]")
            If C < 10 Then 积 = "得" & 积
            If C > 10 And C < 20 Then 积 = Mid(积, 2, 2)
            写作 = B & " × " & A & " = " & C
            读作 = 乘数1 & 乘数2 & 积
            行1 = (A - 1) * 2 + 1
            行2 = (A - 1) * 2 + 2
            列 = B
            Sheet1.Cells(行1, 列).Value = 写作
            Sheet1.Cells(行2, 列).Value = 读作
        Next B
    Next A
End Sub

dongdonggege

39660519 发表于 2023-7-24 08:29
这是以前写的

Sub 生成乘法口诀表()

谢谢，牛。

39660519

dongdonggege 发表于 2023-7-24 09:15
谢谢，牛。

这是几年前给小孩做的，每天练习几张，你可以做个参考