用函数按要求筛选数据并合并成长文本

leangway · 发表于 2023-6-20 13:09

求助大佬，以下要求能用一条公式搞定嘛🤔

函数要求
1、同一部门姓名与新增客户数合并，多个姓名的用顿号分隔（"姓名"&" +"&"新增客户数"）
2、在不更改数据源的情况下，按新增客户数排序生成长文本
3、新增客户数为0的姓名不显示

jisijie630 · 发表于 2023-6-20 13:15

本帖最后由 jisijie630 于 2023-6-20 13:49 编辑

=TEXTJOIN("、",1,TEXT(T(OFFSET(C$1,MOD(LARGE(IF((B$8:B$17=G14)*E$8:E$17,E$8:E$17/1%+ROW($7:$16),0),ROW($1:$9)),100),))&"+"&LARGE((B$8:B$17=G14)*E$8:E$17,ROW($1:$9)),";;;@"))

jivy1212 · 发表于 2023-6-20 13:29

=TEXTJOIN("、",1,FILTER($C$8:$C$17&" +"&$E$8:$E$17,($B$8:$B$17=G8)*($E$8:$E$17<>0)))

复制代码

hugeinfo · 发表于 2023-6-20 13:47

=TEXTJOIN("、",,IF(($B$8:$B$17=G14)*($E$8:$E$17<>0),$C$8:$C$17&"+"&$E$8:$E$17,""))

橒♂蝣 · 发表于 2023-6-20 14:02

=TEXTJOIN("、",1,SORTBY(FILTER($C$8:$C$17&" "&"+"&$E$8:$E$17,($B$8:$B$17=G14)*($E$8:$E$17<>0)),FILTER($E$8:$E$17,($B$8:$B$17=G14)*($E$8:$E$17<>0)),-1))

leangway · 发表于 2023-6-20 14:15

jivy1212 发表于 2023-6-20 13:29

可以可以，简单易懂的公式，但是最终结果没有排序哈，感谢~

zpy2 · 发表于 2023-6-21 08:38

leangway 发表于 2023-6-20 14:15
可以可以，简单易懂的公式，但是最终结果没有排序哈，感谢~

select 部门,group_concat(姓名||' +'||新增客户数,'、') 最终结果 from (select 部门,姓名,新增客户数 from 分组合并之组内按客户数排序 order by 部门,新增客户数 desc) where 新增客户数>0 group by 部门;

ericxzhou · 发表于 2023-6-21 14:32

=TEXTJOIN({" +","、"},1,FILTER(HSTACK($C$8:$C$17,$E$8:$E$17),($B$8:$B$17=G14)*($E$8:$E$17>0)))

		自动登录	找回密码
密码			免费注册

[求助] 用函数按要求筛选数据并合并成长文本

评分

评分

评分